[arch-commits] Commit in eolie/repos (2 files)
Evangelos Foutras
foutrelis at archlinux.org
Mon Jul 23 15:18:37 UTC 2018
Date: Monday, July 23, 2018 @ 15:18:36
Author: foutrelis
Revision: 362978
archrelease: copy trunk to community-staging-x86_64
Added:
eolie/repos/community-staging-x86_64/
eolie/repos/community-staging-x86_64/PKGBUILD
(from rev 362977, eolie/trunk/PKGBUILD)
----------+
PKGBUILD | 43 +++++++++++++++++++++++++++++++++++++++++++
1 file changed, 43 insertions(+)
Copied: eolie/repos/community-staging-x86_64/PKGBUILD (from rev 362977, eolie/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD (rev 0)
+++ community-staging-x86_64/PKGBUILD 2018-07-23 15:18:36 UTC (rev 362978)
@@ -0,0 +1,43 @@
+# $Id$
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+# Contributor: Cédric Bellegarde cedric bellegarde at adishatz dot org
+
+pkgname=eolie
+pkgver=0.9.35
+pkgrel=2
+pkgdesc="Simple web browser for GNOME"
+arch=('x86_64')
+url="https://wiki.gnome.org/Apps/Eolie"
+license=('GPL3')
+depends=('gtkspell3' 'python-cairo' 'python-dateutil' 'python-gobject' 'webkit2gtk')
+makedepends=('git' 'gobject-introspection' 'meson')
+optdepends=('python-beautifulsoup4: Import html bookmarks'
+ 'python-crypto: Firefox Sync support'
+ 'python-fxa: Firefox Sync support'
+ 'python-pyopenssl: Show SSL certificates'
+ 'python-requests-hawk: Firefox Sync support')
+_commit=7cf472ef3622872a9afc6e6b5809477ebd101e27 # tags/0.9.35
+source=("git+https://gitlab.gnome.org/World/eolie.git#commit=$_commit"
+ "git+https://gitlab.gnome.org/gnumdk/eolie-po.git")
+sha256sums=('SKIP'
+ 'SKIP')
+
+pkgver() {
+ cd $pkgname
+ git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+ cd $pkgname
+ git config submodule.subprojects/po.url "$srcdir/eolie-po"
+ git submodule update --init
+}
+
+build() {
+ arch-meson $pkgname build
+ ninja -C build
+}
+
+package() {
+ DESTDIR="$pkgdir" ninja -C build install
+}
More information about the arch-commits
mailing list