[arch-commits] Commit in radare2-cutter/repos (2 files)

[Evangelos Foutras]

    Date: Monday, July 23, 2018 @ 15:20:02
  Author: foutrelis
Revision: 362988

archrelease: copy trunk to community-staging-x86_64

Added:
  radare2-cutter/repos/community-staging-x86_64/
  radare2-cutter/repos/community-staging-x86_64/PKGBUILD
    (from rev 362987, radare2-cutter/trunk/PKGBUILD)

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Copied: radare2-cutter/repos/community-staging-x86_64/PKGBUILD (from rev 362987, radare2-cutter/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-07-23 15:20:02 UTC (rev 362988)
@@ -0,0 +1,43 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Aaron McDaniel (mcd1992) <'aur' at the domain 'fgthou.se'>
+
+pkgname=radare2-cutter
+_gitcommit=806bd6346fe7b9381d3b4b757f935b3810a927db
+pkgver=1.6
+pkgrel=2
+pkgdesc='Qt and C++ GUI for radare2 reverse engineering framework'
+url='https://github.com/radareorg/cutter'
+arch=('x86_64')
+license=('GPL3')
+depends=('radare2' 'capstone' 'qt5-base' 'qt5-svg' 'qt5-webengine' 'icu' 'python')
+makedepends=('git' 'cmake')
+source=(${pkgname}::"git+https://github.com/radareorg/cutter#commit=${_gitcommit}")
+sha512sums=('SKIP')
+
+pkgver() {
+  cd ${pkgname}
+  # remove 'v' prefix on tags; prefix revision with 'r'; replace all '-' with '.'
+  git describe --always --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+prepare() {
+  cd ${pkgname}
+  install -d build
+}
+
+build() {
+  cd ${pkgname}/build
+  qmake ../src/Cutter.pro
+  make
+}
+
+package() {
+  cd ${pkgname}
+  install -Dm 755 build/Cutter -t "${pkgdir}/usr/bin"
+  install -Dm 644 src/Cutter.desktop -t "${pkgdir}/usr/share/applications"
+  install -Dm 644 src/img/cutter.svg -t "${pkgdir}/usr/share/icons/hicolor/scalable/apps"
+  install -d "${pkgdir}/usr/share/doc/${pkgname}"
+  cp -a docs/* "${pkgdir}/usr/share/doc/${pkgname}"
+}
+
+# vim: ts=2 sw=2 et: