[arch-commits] Commit in accerciser/repos (staging-any staging-any/PKGBUILD)

[Felix Yan]

    Date: Monday, July 23, 2018 @ 15:41:52
  Author: felixonmars
Revision: 329443

archrelease: copy trunk to staging-any

Added:
  accerciser/repos/staging-any/
  accerciser/repos/staging-any/PKGBUILD
    (from rev 329442, accerciser/trunk/PKGBUILD)

----------+
 PKGBUILD |   41 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)

Copied: accerciser/repos/staging-any/PKGBUILD (from rev 329442, accerciser/trunk/PKGBUILD)
===================================================================
--- staging-any/PKGBUILD	                        (rev 0)
+++ staging-any/PKGBUILD	2018-07-23 15:41:52 UTC (rev 329443)
@@ -0,0 +1,41 @@
+# $Id$
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+# Contributor: Steve Holmes <steve.holmes88 at gmail.com>
+# Contributor: Giulio Bai <giulio at hewle.com>
+
+pkgname=accerciser
+pkgver=3.22.0
+pkgrel=3
+pkgdesc="Interactive Python accessibility explorer for the GNOME desktop"
+arch=(any)
+url="https://wiki.gnome.org/Apps/Accerciser"
+license=(BSD)
+depends=(python gtk3 python-atspi ipython libwnck3 python-cairo)
+makedepends=(itstool docbook-xsl intltool gnome-common git)
+groups=(gnome-extra)
+_commit=e271fc21ca45edc5c030cd3c0397ff39373ea37e  # tags/3.22.0^0
+source=("git://git.gnome.org/accerciser#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr --sysconfdir=/etc --disable-schemas-compile
+  make
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+  install -m 755 -d "$pkgdir"/usr/share/licenses/$pkgname
+  install -m 644 COPYING "$pkgdir"/usr/share/licenses/$pkgname
+}