[arch-commits] Commit in python-flask-socketio/repos (2 files)

[Felix Yan]

    Date: Monday, July 23, 2018 @ 16:13:56
  Author: felixonmars
Revision: 363128

archrelease: copy trunk to community-staging-any

Added:
  python-flask-socketio/repos/community-staging-any/
  python-flask-socketio/repos/community-staging-any/PKGBUILD
    (from rev 363127, python-flask-socketio/trunk/PKGBUILD)

----------+
 PKGBUILD |   65 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 65 insertions(+)

Copied: python-flask-socketio/repos/community-staging-any/PKGBUILD (from rev 363127, python-flask-socketio/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2018-07-23 16:13:56 UTC (rev 363128)
@@ -0,0 +1,65 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+
+pkgbase=python-flask-socketio
+pkgname=('python-flask-socketio' 'python2-flask-socketio')
+_pkgname=Flask-SocketIO
+pkgver=3.0.1
+pkgrel=2
+pkgdesc='Socket.IO integration for Flask applications'
+url='https://flask-socketio.readthedocs.org/'
+arch=('any')
+license=('MIT')
+makedepends=('python-setuptools' 'python-sphinx' 'python-flask' 'python-eventlet' 'python-socketio'
+             'python2-setuptools' 'python2-sphinx' 'python2-flask' 'python2-eventlet' 'python2-socketio')
+checkdepends=('python-coverage' 'python-pytest'
+              'python2-coverage' 'python2-pytest')
+options=('!makeflags')
+source=(${pkgbase}-${pkgver}.tar.gz::https://github.com/miguelgrinberg/Flask-SocketIO/archive/v${pkgver}.tar.gz)
+sha256sums=('7dd3ee668670efb1fe63edd771613770cbb78b0dfef6f2f6e36f27b674c89fbd')
+sha512sums=('a7818afbf183363ffddcaac634192dc1103289ca3c198622a7f7779986650c8e1347537654018eb3acb71e8ff2e5822d504812b4f369acf6f35fdffc814de23c')
+
+prepare() {
+  cp -ra ${_pkgname}-${pkgver}{,-py2}
+}
+
+build() {
+  (cd ${_pkgname}-${pkgver}
+    python setup.py build
+    make -C docs man text SPHINXBUILD=sphinx-build
+  )
+  (cd ${_pkgname}-${pkgver}-py2
+    python2 setup.py build
+    make -C docs man text SPHINXBUILD=sphinx-build2
+  )
+}
+
+check() {
+  (cd ${_pkgname}-${pkgver}
+    py.test test_socketio.py
+  )
+  (cd ${_pkgname}-${pkgver}-py2
+    py.test2 test_socketio.py
+  )
+}
+
+package_python-flask-socketio() {
+  depends=('python-flask' 'python-eventlet' 'python-socketio')
+  cd ${_pkgname}-${pkgver}
+  python setup.py install -O1 --root="${pkgdir}" --skip-build
+  install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
+  install -Dm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -Dm 644 docs/_build/text/index.txt "${pkgdir}/usr/share/doc/${pkgname}/DOCUMENTATION"
+  install -Dm 644 docs/_build/man/flask-socketio.1 "${pkgdir}/usr/share/man/man1/${pkgname}.1"
+}
+
+package_python2-flask-socketio() {
+  depends=('python2-flask' 'python2-eventlet' 'python-socketio')
+  cd ${_pkgname}-${pkgver}-py2
+  python2 setup.py install -O1 --root="${pkgdir}" --skip-build
+  install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
+  install -Dm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -Dm 644 docs/_build/text/index.txt "${pkgdir}/usr/share/doc/${pkgname}/DOCUMENTATION"
+  install -Dm 644 docs/_build/man/flask-socketio.1 "${pkgdir}/usr/share/man/man1/${pkgname}.1"
+}
+
+# vim: ts=2 sw=2 et: