[arch-commits] Commit in orca/repos (staging-any staging-any/PKGBUILD)

[Evangelos Foutras]

    Date: Monday, July 23, 2018 @ 17:21:17
  Author: foutrelis
Revision: 329468

archrelease: copy trunk to staging-any

Added:
  orca/repos/staging-any/
  orca/repos/staging-any/PKGBUILD
    (from rev 329467, orca/trunk/PKGBUILD)

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Copied: orca/repos/staging-any/PKGBUILD (from rev 329467, orca/trunk/PKGBUILD)
===================================================================
--- staging-any/PKGBUILD	                        (rev 0)
+++ staging-any/PKGBUILD	2018-07-23 17:21:17 UTC (rev 329468)
@@ -0,0 +1,43 @@
+# $Id$
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+# Contributor: William Rea <sillywilly at gmail.com>
+
+pkgname=orca
+pkgver=3.28.1
+pkgrel=2
+pkgdesc="Screen reader for individuals who are blind or visually impaired"
+url="https://wiki.gnome.org/Projects/Orca"
+arch=(any)
+license=(LGPL)
+depends=(gtk3 at-spi2-atk python-atspi python-dbus python-xdg speech-dispatcher liblouis brltty
+         xorg-xmodmap gsettings-desktop-schemas
+         gst-plugins-base # playbin, audiotestsrc, basic decoders
+         gst-plugins-good # pulsesink, more decoders
+)
+makedepends=(itstool intltool git yelp-tools)
+groups=(gnome)
+_commit=7327f64ab52f568fedba0490b7f8c5816798d7c7  # tags/ORCA_3_28_1^0
+source=("git+https://git.gnome.org/browse/orca#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed -e 's/ORCA_//' -e 's/_/\./g' -e 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var
+  make
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+}