[arch-commits] Commit in gedit/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Jan Steffens]

    Date: Monday, July 23, 2018 @ 21:19:32
  Author: heftig
Revision: 329487

archrelease: copy trunk to staging-x86_64

Added:
  gedit/repos/staging-x86_64/
  gedit/repos/staging-x86_64/PKGBUILD
    (from rev 329486, gedit/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: gedit/repos/staging-x86_64/PKGBUILD (from rev 329486, gedit/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2018-07-23 21:19:32 UTC (rev 329487)
@@ -0,0 +1,50 @@
+# $Id$
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+pkgname=gedit
+pkgver=3.28.1
+pkgrel=2
+pkgdesc="GNOME Text Editor"
+url="https://wiki.gnome.org/Apps/Gedit"
+arch=(x86_64)
+license=(GPL)
+depends=(gtksourceview3 gsettings-desktop-schemas libpeas gspell python-gobject dconf)
+makedepends=(yelp-tools intltool vala gobject-introspection gnome-common git gtk-doc)
+optdepends=('gedit-plugins: Additional features')
+groups=(gnome)
+_commit=59a804accea4010cab5acbd4f5bb30838a3ad248  # tags/3.28.1^0
+source=("git+https://git.gnome.org/browse/gedit#commit=$_commit"
+        "git+https://git.gnome.org/browse/libgd")
+sha256sums=('SKIP'
+            'SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+
+  git submodule init
+  git config --local submodule.libgd.url "$srcdir/libgd"
+  git submodule update
+
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr \
+      --sysconfdir=/etc --localstatedir=/var \
+      --libexecdir=/usr/lib --disable-updater --disable-schemas-compile \
+      --enable-python --enable-gtk-doc
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+package(){
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+}