[arch-commits] Commit in tracker-miners/repos/extra-x86_64 (PKGBUILD PKGBUILD)
Jan Steffens
heftig at archlinux.org
Mon Jul 23 21:50:50 UTC 2018
Date: Monday, July 23, 2018 @ 21:50:49
Author: heftig
Revision: 329495
archrelease: copy trunk to extra-x86_64
Added:
tracker-miners/repos/extra-x86_64/PKGBUILD
(from rev 329494, tracker-miners/trunk/PKGBUILD)
Deleted:
tracker-miners/repos/extra-x86_64/PKGBUILD
----------+
PKGBUILD | 99 +++++++++++++++++++++++++------------------------------------
1 file changed, 42 insertions(+), 57 deletions(-)
Deleted: PKGBUILD
===================================================================
--- PKGBUILD 2018-07-23 21:50:26 UTC (rev 329494)
+++ PKGBUILD 2018-07-23 21:50:49 UTC (rev 329495)
@@ -1,57 +0,0 @@
-# $Id$
-# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
-
-pkgname=tracker-miners
-pkgver=2.0.5
-pkgrel=1
-pkgdesc="Collection of data extractors for Tracker/Nepomuk"
-url="https://wiki.gnome.org/Projects/Tracker"
-arch=(x86_64)
-license=(GPL)
-depends=(tracker gst-plugins-base-libs exempi flac libexif libcue libgrss libgsf libgxps
- libiptcdata libosinfo libvorbis poppler-glib taglib totem-plparser giflib)
-makedepends=(intltool git python)
-groups=(gnome)
-_commit=d3ee83ad9bde8ee16b8a3dec4d8f459811921db1 # tags/2.0.5^0
-source=("git+https://gitlab.gnome.org/GNOME/tracker-miners.git#commit=$_commit")
-sha256sums=('SKIP')
-
-pkgver() {
- cd $pkgname
- git describe --tags | sed 's/-/+/g'
-}
-
-prepare() {
- cd $pkgname
- NOCONFIGURE=1 ./autogen.sh
-}
-
-build() {
- cd $pkgname
- ./configure \
- --prefix=/usr \
- --sysconfdir=/etc \
- --localstatedir=/var \
- --libexecdir=/usr/lib \
- --enable-unit-tests \
- --enable-functional-tests \
- --enable-libflac \
- --enable-libvorbis \
- --enable-guarantee-metadata
- sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
- make
-}
-
-check() {
- cd $pkgname
- # Many tests are broken:
- # - Assume schemas are installed
- # - Assume services are autolaunched
- dbus-run-session make -k check || :
-}
-
-package() {
- cd $pkgname
- make DESTDIR="$pkgdir" install
- rm -r "$pkgdir/usr/share/tracker-tests"
-}
Copied: tracker-miners/repos/extra-x86_64/PKGBUILD (from rev 329494, tracker-miners/trunk/PKGBUILD)
===================================================================
--- PKGBUILD (rev 0)
+++ PKGBUILD 2018-07-23 21:50:49 UTC (rev 329495)
@@ -0,0 +1,42 @@
+# $Id$
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+
+pkgname=tracker-miners
+pkgver=2.1.0
+pkgrel=1
+pkgdesc="Collection of data extractors for Tracker/Nepomuk"
+url="https://wiki.gnome.org/Projects/Tracker"
+arch=(x86_64)
+license=(GPL)
+depends=(tracker gst-plugins-base-libs exempi flac libexif libcue libgrss libgsf libgxps
+ libiptcdata libosinfo libvorbis poppler-glib taglib totem-plparser giflib)
+makedepends=(intltool git python meson)
+groups=(gnome)
+_commit=24d32b563e6bfba4558c8bcb4724b19a14e1513b # tags/2.1.0^0
+source=("git+https://gitlab.gnome.org/GNOME/tracker-miners.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+ cd $pkgname
+ git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+ cd $pkgname
+}
+
+build() {
+ arch-meson $pkgname build
+ ninja -C build
+}
+
+check() {
+ # Many tests are broken:
+ # - Assume schemas are installed
+ # - Assume services are autolaunched
+ dbus-run-session meson test -C build || :
+}
+
+package() {
+ DESTDIR="$pkgdir" meson install -C build
+}
More information about the arch-commits
mailing list