[arch-commits] Commit in python-genshi/repos/community-x86_64 (PKGBUILD PKGBUILD)

[Eli Schwartz]

    Date: Wednesday, July 25, 2018 @ 04:30:13
  Author: eschwartz
Revision: 363336

archrelease: copy trunk to community-x86_64

Added:
  python-genshi/repos/community-x86_64/PKGBUILD
    (from rev 363335, python-genshi/trunk/PKGBUILD)
Deleted:
  python-genshi/repos/community-x86_64/PKGBUILD

----------+
 PKGBUILD |   72 +++++++++++++++++++++++++++++++++++++------------------------
 1 file changed, 44 insertions(+), 28 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2018-07-25 04:28:14 UTC (rev 363335)
+++ PKGBUILD	2018-07-25 04:30:13 UTC (rev 363336)
@@ -1,28 +0,0 @@
-# $Id$
-# Maintainer: Sergej Pupykin <pupykin.s+arch at gmail.com>
-# Contributor : Todd Maynard <arch at toddmaynard.com>
-
-pkgname=python2-genshi
-pkgver=0.7
-pkgrel=4
-pkgdesc="Python toolkit for stream-based generation of output for the web."
-url="https://genshi.edgewall.org/"
-license=("BSD")
-arch=('x86_64')
-depends=('python2')
-makedepends=('python2-setuptools')
-conflicts=('python-genshi<=0.6-3')
-replaces=('python-genshi<=0.6-3')
-source=("https://ftp.edgewall.org/pub/genshi/Genshi-$pkgver.tar.gz")
-md5sums=('54e64dd69da3ec961f86e686e0848a82')
-
-build() {
-  cd "$srcdir"/Genshi-${pkgver}
-  python2 setup.py build
-}
-
-package() {
-  cd "$srcdir"/Genshi-${pkgver}
-  python2 setup.py install --root="$pkgdir" --optimize=1 --skip-build
-  install -Dm644 COPYING "$pkgdir"/usr/share/licenses/$pkgname/COPYING
-}

Copied: python-genshi/repos/community-x86_64/PKGBUILD (from rev 363335, python-genshi/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2018-07-25 04:30:13 UTC (rev 363336)
@@ -0,0 +1,44 @@
+# $Id$
+# Maintainer: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Contributor : Todd Maynard <arch at toddmaynard.com>
+
+pkgname=(python-genshi python2-genshi)
+pkgver=0.7
+pkgrel=5
+_commit=4f491e42a97395f64d968df756172ea0b12e5d85
+pkgdesc="Python toolkit for stream-based generation of output for the web."
+url="https://genshi.edgewall.org/"
+license=("BSD")
+arch=('x86_64')
+makedepends=('python-setuptools' 'python2-setuptools')
+source=("https://github.com/edgewall/genshi/archive/${_commit}.tar.gz")
+sha256sums=('d69c8807789822a354aa9528a37e00db6c6d5df16de4a705c46aa2d4bed24a6d')
+
+prepare() {
+    # uses 2to3 so need to build python2/python3 in separate dirs
+    cp -a "${srcdir}"/genshi-${_commit}{,-py2}
+}
+
+build() {
+    cd "${srcdir}"/genshi-${_commit}
+    python setup.py build
+
+    cd "${srcdir}"/genshi-${_commit}-py2
+    python2 setup.py build
+}
+
+package_python-genshi() {
+    depends=('python')
+
+    cd "${srcdir}"/genshi-${_commit}
+    python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
+    install -Dm644 COPYING "${pkgdir}"/usr/share/licenses/${pkgname}/COPYING
+}
+
+package_python2-genshi() {
+    depends=('python2')
+
+    cd "${srcdir}"/genshi-${_commit}-py2
+    python2 setup.py install --root="${pkgdir}" --optimize=1 --skip-build
+    install -Dm644 COPYING "${pkgdir}"/usr/share/licenses/${pkgname}/COPYING
+}