[arch-commits] Commit in aubio/repos (3 files)

[Eli Schwartz]

    Date: Wednesday, July 25, 2018 @ 16:40:11
  Author: eschwartz
Revision: 363393

archrelease: copy trunk to community-staging-x86_64

Added:
  aubio/repos/community-staging-x86_64/
  aubio/repos/community-staging-x86_64/0001-Fix-build-with-FFmpeg-4.0.patch
    (from rev 363392, aubio/trunk/0001-Fix-build-with-FFmpeg-4.0.patch)
  aubio/repos/community-staging-x86_64/PKGBUILD
    (from rev 363392, aubio/trunk/PKGBUILD)

--------------------------------------+
 0001-Fix-build-with-FFmpeg-4.0.patch |   28 +++++++++
 PKGBUILD                             |  100 +++++++++++++++++++++++++++++++++
 2 files changed, 128 insertions(+)

Copied: aubio/repos/community-staging-x86_64/0001-Fix-build-with-FFmpeg-4.0.patch (from rev 363392, aubio/trunk/0001-Fix-build-with-FFmpeg-4.0.patch)
===================================================================
--- community-staging-x86_64/0001-Fix-build-with-FFmpeg-4.0.patch	                        (rev 0)
+++ community-staging-x86_64/0001-Fix-build-with-FFmpeg-4.0.patch	2018-07-25 16:40:11 UTC (rev 363393)
@@ -0,0 +1,28 @@
+From 5690daf759b473b9d13b4547ef37adc2695cf524 Mon Sep 17 00:00:00 2001
+From: James Cowgill <jcowgill at jcowgill.uk>
+Date: Sun, 25 Feb 2018 14:23:25 +0000
+Subject: [PATCH] Fix build with FFmpeg 4.0
+
+---
+ src/io/source_avcodec.c | 4 ++++
+ 1 file changed, 4 insertions(+)
+
+diff --git a/src/io/source_avcodec.c b/src/io/source_avcodec.c
+index ccdce807..8197445c 100644
+--- a/src/io/source_avcodec.c
++++ b/src/io/source_avcodec.c
+@@ -58,7 +58,11 @@
+ #include "fmat.h"
+ #include "source_avcodec.h"
+ 
++#if LIBAVCODEC_VERSION_INT < AV_VERSION_INT(56, 56, 0)
+ #define AUBIO_AVCODEC_MAX_BUFFER_SIZE FF_MIN_BUFFER_SIZE
++#else
++#define AUBIO_AVCODEC_MAX_BUFFER_SIZE AV_INPUT_BUFFER_MIN_SIZE
++#endif
+ 
+ struct _aubio_source_avcodec_t {
+   uint_t hop_size;
+-- 
+2.17.0
+

Copied: aubio/repos/community-staging-x86_64/PKGBUILD (from rev 363392, aubio/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-07-25 16:40:11 UTC (rev 363393)
@@ -0,0 +1,100 @@
+# $Id$
+# Maintainer: David Runge <dave at sleepmap.de>
+# Contributor: Ray Rashif <schiv at archlinux.org>
+# Contributor: Tobias Kieslich tobias [funnychar] archlinux org
+
+pkgbase=aubio
+pkgname=('aubio' 'python-aubio' 'python2-aubio')
+pkgver=0.4.6
+pkgrel=7
+pkgdesc="A tool for extracting annotations from audio signals"
+arch=('x86_64')
+url="https://aubio.org/"
+license=('GPL3')
+makedepends=('doxygen' 'ffmpeg' 'fftw' 'jack' 'libsamplerate' 'libsndfile'
+'python-numpy' 'python-setuptools' 'python-sphinx' 'python2-numpy'
+'python2-setuptools' 'python2-sphinx' 'txt2man')
+checkdepends=('python-nose2' 'python2-nose2')
+source=("https://${pkgname}.org/pub/${pkgname}-${pkgver}.tar.bz2"
+        "0001-Fix-build-with-FFmpeg-4.0.patch")
+sha512sums=('0e5cab0c88d51f2fb70c0d85e1c067a7b3758fbffdbd5026686726379aa36203adb63ed3f8e40c83ea02930e0ffc4e6c246803f1d518d448d47a01984678e77d'
+            '46fadc289bf6ae5b57d9ba15de0e3a892e255b26c0420efea6d0acdf39cd553d7e8c4ae9a2cde0fdfe0d99b3f05ef18b41e07288174c0fbf49c8d16f8d766f9a')
+
+prepare() {
+  cd "${pkgname[0]}-${pkgver}"
+  # apply patch to build with ffmpeg >= 4.0
+  patch -Np1 -i "../0001-Fix-build-with-FFmpeg-4.0.patch"
+  cd ..
+  cp -av "${pkgname[0]}-${pkgver}" "${pkgname[1]}-${pkgver}"
+  cp -av "${pkgname[0]}-${pkgver}" "${pkgname[2]}-${pkgver}"
+  cd "${pkgname[2]}-${pkgver}"
+  # python2 shebang
+  sed -e '1s/python/&2/' \
+    -i "python/lib/${pkgname}/"{__init__,cmd,cut}.py \
+    -i "python/tests/"*.py
+}
+
+build() {
+  cd "${pkgname[0]}-${pkgver}"
+  echo "$(pwd)"
+  python2 waf configure --prefix=/usr \
+    --enable-fftw3 \
+    --htmldir=/usr/share/doc/${pkgname} \
+    --docdir=/usr/share/doc/${pkgname} \
+    --libdir=/usr/lib
+  python2 waf build
+  cd ../"${pkgname[1]}-${pkgver}"
+  python setup.py build
+  cd ../"${pkgname[2]}-${pkgver}"
+  python2 setup.py build
+}
+
+check() {
+  cd "${pkgname[1]}-${pkgver}"
+  PYTHONPATH="${PWD}/build/lib.linux-${CARCH}-3.7:${PYTHONPATH}" python setup.py test
+
+  cd ../"${pkgname[2]}-${pkgver}"
+  PYTHONPATH="${PWD}/build/lib.linux-${CARCH}-2.7:${PYTHONPATH}" python2 setup.py test
+}
+
+package_aubio() {
+  pkgdesc="A tool for extracting annotations from audio signals"
+  depends=('ffmpeg' 'fftw' 'jack' 'libsamplerate')
+  optdepends=('python2-numpy: Python 2.x interface'
+              'python-numpy: Python 3.x interface')
+  groups=('pro-audio')
+  cd "${pkgname}-${pkgver}"
+  python2 waf --destdir="${pkgdir}" install
+  # move doc, as waf configure doesn't honor the htmldir and docdir settings
+  mv -v "${pkgdir}/usr/share/doc/lib${pkgname}-doc" \
+    "${pkgdir}/usr/share/doc/${pkgname}"
+  install -t "${pkgdir}/usr/share/doc/${pkgname}/" \
+    -vDm 644 {AUTHORS,ChangeLog,README.md}
+}
+
+package_python-aubio() {
+  pkgdesc="Python 3.x bindings for aubio."
+  depends=('aubio' 'python-numpy' 'python-setuptools')
+  cd "${pkgname}-${pkgver}"
+  python setup.py install --skip-build \
+    --optimize=1 \
+    --root="${pkgdir}"
+  install -t "${pkgdir}/usr/share/doc/${pkgname}/" \
+    -vDm 644 {AUTHORS,ChangeLog,README.md}
+}
+
+package_python2-aubio() {
+  pkgdesc="Python 2.x bindings for aubio."
+  depends=('aubio' 'python2-numpy' 'python2-setuptools')
+  cd "${pkgname}-${pkgver}"
+  python2 setup.py install --skip-build \
+    --optimize=1 \
+    --root="${pkgdir}"
+  install -t "${pkgdir}/usr/share/doc/${pkgname}/" \
+    -vDm 644 {AUTHORS,ChangeLog,README.md}
+  # move duplicates
+  mv -v "${pkgdir}/usr/bin/aubio" "${pkgdir}/usr/bin/aubio2"
+  mv -v "${pkgdir}/usr/bin/aubiocut" "${pkgdir}/usr/bin/aubiocut2"
+}
+
+# vim:set ts=2 sw=2 et: