[arch-commits] Commit in sratom/repos (2 files)
David Runge
dvzrv at archlinux.org
Thu Jul 26 06:59:07 UTC 2018
Date: Thursday, July 26, 2018 @ 06:59:07
Author: dvzrv
Revision: 363467
archrelease: copy trunk to community-staging-x86_64
Added:
sratom/repos/community-staging-x86_64/
sratom/repos/community-staging-x86_64/PKGBUILD
(from rev 363466, sratom/trunk/PKGBUILD)
----------+
PKGBUILD | 49 +++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 49 insertions(+)
Copied: sratom/repos/community-staging-x86_64/PKGBUILD (from rev 363466, sratom/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD (rev 0)
+++ community-staging-x86_64/PKGBUILD 2018-07-26 06:59:07 UTC (rev 363467)
@@ -0,0 +1,49 @@
+# $Id$
+# Maintainer: David Runge <dave at sleepmap.de>
+# Contributor: Ray Rashif <schiv at archlinux.org>
+# Contributor: speps <speps at aur dot archlinux dot org>
+
+pkgname=sratom
+pkgver=0.6.2
+pkgrel=1
+pkgdesc="An LV2 Atom RDF serialisation library"
+arch=('x86_64')
+url="https://drobilla.net/software/sratom/"
+license=('custom:ISC')
+depends=('sord')
+makedepends=('lv2' 'python2')
+source=("https://download.drobilla.net/${pkgname}-${pkgver}.tar.bz2"{,.sig})
+sha512sums=('356e1dfde07fcc3eff99186ff79501557572f5d73338fd096bf639a82d1d4fe3c0e790627c8eb088053e4a2aeed4e548aca0a5572d1ab26316cfdb13374f10ac'
+ 'SKIP')
+validpgpkeys=('907D226E7E13FA337F014A083672782A9BF368F3')
+
+prepare() {
+ cd "${pkgname}-${pkgver}"
+ # remove local ldconfig call
+ sed -i '/ldconfig/d' wscript
+}
+
+build() {
+ cd "${pkgname}-${pkgver}"
+ python2 waf configure --prefix=/usr \
+ --test
+ python2 waf build
+}
+
+check() {
+ cd "${pkgname}-${pkgver}"
+ python2 waf test --verbose-tests
+}
+
+
+package() {
+ cd "${pkgname}-${pkgver}"
+ python2 waf install --destdir="${pkgdir}"
+ # license
+ install -vDm 644 COPYING \
+ "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+ # docs
+ install -t "${pkgdir}/usr/share/doc/${pkgname}" \
+ -vDm 644 {NEWS,README}
+}
+# vim:set ts=2 sw=2 et:
More information about the arch-commits
mailing list