[arch-commits] Commit in haskell-http-client/repos (2 files)

[Felix Yan]

    Date: Sunday, July 29, 2018 @ 06:43:09
  Author: felixonmars
Revision: 364262

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-http-client/repos/community-staging-x86_64/
  haskell-http-client/repos/community-staging-x86_64/PKGBUILD
    (from rev 364261, haskell-http-client/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: haskell-http-client/repos/community-staging-x86_64/PKGBUILD (from rev 364261, haskell-http-client/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-07-29 06:43:09 UTC (rev 364262)
@@ -0,0 +1,47 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=http-client
+pkgname=haskell-http-client
+pkgver=0.5.13.1
+pkgrel=12
+pkgdesc="An HTTP client engine"
+url="https://github.com/snoyberg/http-client"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-blaze-builder' 'haskell-case-insensitive' 'haskell-cookie'
+         'haskell-exceptions' 'haskell-http-types' 'haskell-memory' 'haskell-mime-types'
+         'haskell-network' 'haskell-network-uri' 'haskell-random' 'haskell-streaming-commons'
+        )
+makedepends=('ghc' 'haskell-async' 'haskell-hspec' 'haskell-monad-control' 'haskell-zlib')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('135bbbbc32dbc1613308c55347f4d8a0ba577d6ca8b522eb3aac7b96df92577a3c101464e89fc77c348b18cf040104176036adee7710bd9b4ce31aa0e5012e0a')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid -fnetwork-uri
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}