[arch-commits] Commit in python-gevent/repos (2 files)

[Felix Yan]

    Date: Friday, June 1, 2018 @ 17:26:21
  Author: felixonmars
Revision: 336325

archrelease: copy trunk to community-testing-x86_64

Added:
  python-gevent/repos/community-testing-x86_64/
  python-gevent/repos/community-testing-x86_64/PKGBUILD
    (from rev 336324, python-gevent/trunk/PKGBUILD)

----------+
 PKGBUILD |   78 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 78 insertions(+)

Copied: python-gevent/repos/community-testing-x86_64/PKGBUILD (from rev 336324, python-gevent/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2018-06-01 17:26:21 UTC (rev 336325)
@@ -0,0 +1,78 @@
+# $Id: PKGBUILD 70305 2012-05-04 08:21:08Z mtorromeo $
+# Maintainer: Massimiliano Torromeo <massimiliano.torromeo at gmail.com>
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Ralf Schmitt <ralf at systemexit.de>
+
+pkgbase=python-gevent
+pkgname=(python-gevent python2-gevent)
+pkgver=1.3.2.post0
+pkgrel=1
+arch=('x86_64')
+pkgdesc="Python network library that uses greenlet and libev for easy and scalable concurrency"
+license=("MIT")
+url="http://www.gevent.org/"
+makedepends=('python-greenlet' 'python2-greenlet' 'cython' 'cython2')
+checkdepends=('lsof' 'python-perf' 'python2-perf' 'python2-virtualenv' 'python-objgraph'
+              'python2-objgraph' 'python-zope-interface' 'python2-zope-interface' 'python-dnspython'
+              'python2-dnspython' 'python-requests' 'python2-requests' 'python-zope-event'
+              'python2-zope-event' 'python2-mock')
+source=("$pkgbase-$pkgver.tar.gz::https://github.com/gevent/gevent/archive/$pkgver.tar.gz")
+sha512sums=('187d38b0b92b91b10aff4669d7c696b57d9cf23fd0c32d49a7b2a9657431a8d7004145ec578691976d6c4cf8f3ade567720e2066154fc1cedc3fe1d29cabc4a4')
+
+prepare() {
+  sed -e 's/C.UTF-8/en_US.UTF-8/' -e '/@which/d' -i gevent-$pkgver/Makefile
+
+  cp -a gevent-$pkgver{,-py2}
+}
+
+build() {
+  cd "$srcdir"/gevent-$pkgver
+
+  EMBED=1 \
+  CYTHON=cython \
+  PYTHON=python \
+  python setup.py build
+
+  cd "$srcdir"/gevent-$pkgver-py2
+
+  EMBED=1 \
+  CYTHON=cython2 \
+  PYTHON=python2 \
+  python2 setup.py build
+}
+
+check() {
+  (
+    cd "$srcdir"/gevent-$pkgver
+    pyvenv "$srcdir/pyvenv" --system-site-packages
+    . "$srcdir/pyvenv/bin/activate"
+    export PYTHONPATH="$PYTHONPATH:/usr/lib/python3.6/site-packages"
+    python setup.py install
+    make bench alltest
+  ) || warning "Tests failed"
+
+  (
+    cd "$srcdir"/gevent-$pkgver-py2
+    virtualenv2 "$srcdir/pyvenv" --system-site-packages
+    . "$srcdir/pyvenv/bin/activate"
+    export PYTHONPATH="$PYTHONPATH:/usr/lib/python2.7/site-packages"
+    python setup.py install
+    PYTHON=python2 make bench alltest
+  ) || warning "Tests failed"
+}
+
+package_python-gevent() {
+  depends=('python-greenlet')
+
+  cd gevent-$pkgver
+  python setup.py install -O1 --root="$pkgdir"
+  install -Dm0644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-gevent() {
+  depends=('python2-greenlet')
+
+  cd gevent-$pkgver-py2
+  python2 setup.py install -O1 --root="$pkgdir"
+  install -Dm0644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}