[arch-commits] Commit in drbd-utils/repos (2 files)
Antonio Rojas
arojas at archlinux.org
Sun Jun 10 07:45:40 UTC 2018
Date: Sunday, June 10, 2018 @ 07:45:40
Author: arojas
Revision: 342199
archrelease: copy trunk to community-testing-x86_64
Added:
drbd-utils/repos/community-testing-x86_64/
drbd-utils/repos/community-testing-x86_64/PKGBUILD
(from rev 342198, drbd-utils/trunk/PKGBUILD)
----------+
PKGBUILD | 60 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 60 insertions(+)
Copied: drbd-utils/repos/community-testing-x86_64/PKGBUILD (from rev 342198, drbd-utils/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD (rev 0)
+++ community-testing-x86_64/PKGBUILD 2018-06-10 07:45:40 UTC (rev 342199)
@@ -0,0 +1,60 @@
+# $Id$
+# Maintainer: Sébastien Luttringer
+
+pkgname=drbd-utils
+pkgver=9.4.0
+pkgrel=1
+arch=('x86_64')
+pkgdesc='Userland tools for Distributed Replicated Block Device'
+url='https://www.drbd.org'
+license=('GPL2')
+depends=('perl' 'bash')
+makedepends=('libxslt' 'systemd')
+conflicts=('drbd')
+replaces=('drbd')
+source=("https://www.drbd.org/download/drbd/utils/drbd-utils-$pkgver.tar.gz")
+backup=('etc/drbd.conf' 'etc/drbd.d/global_common.conf')
+md5sums=('f731d90863be8002379d2ed4bc26b1e8')
+
+build() {
+ cd $pkgname-$pkgver
+ ./configure \
+ --prefix=/usr \
+ --localstatedir=/var \
+ --sysconfdir=/etc \
+ --sbindir=/usr/bin \
+ --libdir=/usr/lib \
+ --with-distro=generic \
+ --with-bashcompletion \
+ --with-initscripttype=systemd \
+ --with-udev \
+ --without-rgmanager \
+ --without-pacemaker \
+ --without-heartbeat \
+ --without-83support \
+ --without-xen
+ make
+}
+
+package() {
+ make -C $pkgname-$pkgver DESTDIR="$pkgdir" install
+
+ cd "$pkgdir"
+
+ # move /lib files under /usr/lib
+ mv lib/drbd/* usr/lib/drbd
+ rmdir lib/drbd lib
+
+ # move bash completion
+ install -dm 755 usr/share/bash-completion
+ mv etc/bash_completion.d usr/share/bash-completion/completions
+
+ # remove /var/lock
+ rmdir var/lock
+
+ # autoload module
+ install -Dm 644 /dev/null usr/lib/modules-load.d/drbd.conf
+ echo 'drbd' > usr/lib/modules-load.d/drbd.conf
+}
+
+# vim:set ts=2 sw=2 et:
More information about the arch-commits
mailing list