[arch-commits] Commit in breeze/repos (testing-x86_64 testing-x86_64/PKGBUILD)
Antonio Rojas
arojas at archlinux.org
Tue Jun 12 09:07:38 UTC 2018
Date: Tuesday, June 12, 2018 @ 09:07:38
Author: arojas
Revision: 326767
archrelease: copy trunk to testing-x86_64
Added:
breeze/repos/testing-x86_64/
breeze/repos/testing-x86_64/PKGBUILD
(from rev 326766, breeze/trunk/PKGBUILD)
----------+
PKGBUILD | 64 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 64 insertions(+)
Copied: breeze/repos/testing-x86_64/PKGBUILD (from rev 326766, breeze/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD (rev 0)
+++ testing-x86_64/PKGBUILD 2018-06-12 09:07:38 UTC (rev 326767)
@@ -0,0 +1,64 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+
+pkgbase=breeze
+pkgname=(breeze breeze-kde4)
+pkgver=5.13.0
+pkgrel=1
+arch=(x86_64)
+url='https://www.kde.org/workspaces/plasmadesktop/'
+license=(LGPL)
+makedepends=(extra-cmake-modules frameworkintegration kdelibs automoc4 kdecoration kcmutils plasma-framework)
+source=("https://download.kde.org/stable/plasma/$pkgver/$pkgbase-$pkgver.tar.xz"{,.sig})
+sha256sums=('a03193bbc1c7a385c302ba988fb79996edcb09b5673ac399a4062e0409825129'
+ 'SKIP')
+validpgpkeys=('2D1D5B0588357787DE9EE225EC94D18F7F05997E' # Jonathan Riddell
+ '0AAC775BB6437A8D9AF7A3ACFE0784117FBCE11D' # Bhushan Shah <bshah at kde.org>
+ 'D07BD8662C56CB291B316EB2F5675605C74E02CF' # David Edmundson
+ '1FA881591C26B276D7A5518EEAAF29B42A678C20') # Marco Martin <notmart at gmail.com>
+
+prepare() {
+ mkdir -p build{,-kde4}
+}
+
+build() {
+ cd build
+ cmake ../$pkgbase-$pkgver \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DCMAKE_INSTALL_LIBDIR=lib \
+ -DBUILD_TESTING=OFF
+ make
+
+ cd ../build-kde4
+ cmake ../$pkgbase-$pkgver \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DUSE_KDE4=ON \
+ -DBUILD_TESTING=OFF
+ make
+}
+
+package_breeze() {
+ depends=(frameworkintegration kdecoration breeze-icons kwayland hicolor-icon-theme)
+ pkgdesc='Artwork, styles and assets for the Breeze visual style for the Plasma Desktop'
+ optdepends=('breeze-kde4: Breeze widget style for KDE4 applications'
+ 'breeze-gtk: Breeze widget style for GTK applications'
+ 'kcmutils: for breeze-settings')
+ groups=(plasma)
+
+ cd build
+ make DESTDIR="$pkgdir" install
+}
+
+package_breeze-kde4() {
+ pkgdesc='Breeze widget style for KDE4 applications'
+ depends=(kdelibs)
+
+ cd build-kde4
+ make DESTDIR="$pkgdir" install
+
+ # needed for pure Qt4 apps
+ install -d "$pkgdir"/usr/lib/qt4/plugins/styles
+ ln -s /usr/lib/kde4/plugins/styles/breeze.so "$pkgdir"/usr/lib/qt4/plugins/styles
+}
More information about the arch-commits
mailing list