[arch-commits] Commit in kde-cli-tools/repos (testing-x86_64 testing-x86_64/PKGBUILD)

[Antonio Rojas]

    Date: Tuesday, June 12, 2018 @ 09:08:59
  Author: arojas
Revision: 326774

archrelease: copy trunk to testing-x86_64

Added:
  kde-cli-tools/repos/testing-x86_64/
  kde-cli-tools/repos/testing-x86_64/PKGBUILD
    (from rev 326773, kde-cli-tools/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: kde-cli-tools/repos/testing-x86_64/PKGBUILD (from rev 326773, kde-cli-tools/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2018-06-12 09:08:59 UTC (rev 326774)
@@ -0,0 +1,44 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+
+pkgname=kde-cli-tools
+pkgver=5.13.0
+pkgrel=1
+pkgdesc="Tools based on KDE Frameworks 5 to better interact with the system"
+arch=(x86_64)
+url='https://www.kde.org/workspaces/plasmadesktop/'
+license=(LGPL)
+depends=(kdesu kcmutils kinit kactivities)
+makedepends=(extra-cmake-modules kdoctools plasma-workspace)
+optdepends=('plasma-workspace: for kcmshell5')
+groups=(plasma)
+source=("https://download.kde.org/stable/plasma/$pkgver/$pkgname-$pkgver.tar.xz"{,.sig})
+sha256sums=('fa2ff18738725d1be4d4134bfa7b8225ff94305f7355b0903848ac681b645262'
+            'SKIP')
+validpgpkeys=('2D1D5B0588357787DE9EE225EC94D18F7F05997E'  # Jonathan Riddell
+              '0AAC775BB6437A8D9AF7A3ACFE0784117FBCE11D'  # Bhushan Shah <bshah at kde.org>
+              'D07BD8662C56CB291B316EB2F5675605C74E02CF'  # David Edmundson
+              '1FA881591C26B276D7A5518EEAAF29B42A678C20') # Marco Martin <notmart at gmail.com>
+
+prepare() {
+  mkdir -p build
+}
+
+build() {
+  cd build
+  cmake ../$pkgname-$pkgver \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DCMAKE_INSTALL_LIBEXECDIR=lib \
+    -DBUILD_TESTING=OFF
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="$pkgdir" install
+
+  ln -s /usr/lib/kf5/kdesu "$pkgdir"/usr/bin/
+}