[arch-commits] Commit in gmic/repos/community-x86_64 (3 files)
Antonio Rojas
arojas at archlinux.org
Thu Jun 21 15:03:03 UTC 2018
Date: Thursday, June 21, 2018 @ 15:03:03
Author: arojas
Revision: 344310
archrelease: copy trunk to community-x86_64
Added:
gmic/repos/community-x86_64/PKGBUILD
(from rev 344309, gmic/trunk/PKGBUILD)
gmic/repos/community-x86_64/zart-qt5.11.patch
(from rev 344309, gmic/trunk/zart-qt5.11.patch)
Deleted:
gmic/repos/community-x86_64/PKGBUILD
-------------------+
PKGBUILD | 148 +++++++++++++++++++++++++++-------------------------
zart-qt5.11.patch | 22 +++++++
2 files changed, 101 insertions(+), 69 deletions(-)
Deleted: PKGBUILD
===================================================================
--- PKGBUILD 2018-06-21 15:02:33 UTC (rev 344309)
+++ PKGBUILD 2018-06-21 15:03:03 UTC (rev 344310)
@@ -1,69 +0,0 @@
-# Maintainer: Antonio Rojas <arojas at archlinux.org>
-# Contributor: Sergej Pupykin <pupykin.s+arch at gmail.com>
-# Contributor: Jan "heftig" Steffens <jan.steffens at gmail.com>
-# Contributor: farid <farid at archlinuc-br.org>
-# Contributor: Archie <Mymaud at gmail.com>
-
-pkgbase=gmic
-pkgname=(gmic zart gimp-plugin-gmic krita-plugin-gmic)
-pkgver=2.2.3
-_commit=34f7e483a819dd2af4f772d0f748928119f22f6d
-pkgrel=1
-arch=(x86_64)
-url="http://gmic.eu/"
-license=(custom:CeCILL)
-makedepends=(gimp qt5-base fftw openexr opencv git)
-source=("https://gmic.eu/files/source/gmic_$pkgver.tar.gz"
- git://github.com/c-koi/zart.git#commit=$_commit
- gmic-qt-v.$pkgver.tar.gz::"https://github.com/c-koi/gmic-qt/archive/v.$pkgver.tar.gz")
-sha256sums=('366e348ebfa85354e99b19eecf2e6b10d445901132eb73c84b18fb23af23f0e8'
- 'SKIP'
- '72a6ad1f1acb15f4d9417c9cd16615160d04f764aaa2b0206fa6c80587fb91af')
-
-prepare() {
- mv gmic-$pkgver gmic
- mv gmic-qt-v.$pkgver gmic-qt
-
- sed -e 's|/etc/bash_completion.d|/usr/share/bash-completion/completions|g' -i gmic/src/Makefile
- sed -e 's|-Ofast|-O2 -fno-fast-math|g' -i gmic-qt/gmic_qt.pro
- sed -e 's/pkg-config opencv --libs ||//' -e 's/-lopencv_highgui/-lopencv_videoio/' -i gmic/src/Makefile # fix overlinking
-}
-
-build() {
- cd gmic
- make -C src all WGET=/bin/true -j1
-}
-
-package_gmic() {
- pkgdesc="GREYC's Magic Image Converter: image processing framework"
- depends=(opencv fftw curl)
- optdepends=('qt5-base: for the Qt UI')
-
- cd gmic/src
- make DESTDIR="$pkgdir" install
- install -Dm644 ../COPYING "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
- rm -r "$pkgdir"/usr/{bin/zart,lib/gimp,bin/gmic_krita_qt}
-}
-
-package_zart() {
- pkgdesc="A GUI for G'MIC real-time manipulations on the output of a webcam"
- depends=(opencv fftw qt5-base)
-
- install -Dm755 gmic/zart/zart -t "$pkgdir"/usr/bin
- install -Dm644 zart/Licence_CeCILL_V2-en.html -t "$pkgdir"/usr/share/licenses/$pkgname
-}
-
-package_gimp-plugin-gmic() {
- pkgdesc="Gimp plugin for the G'MIC image processing framework"
- depends=(gimp fftw qt5-base curl)
-
- install -Dm755 gmic/gmic-qt/gmic_gimp_qt "$pkgdir"/usr/lib/gimp/2.0/plug-ins/gmic_gimp
- install -Dm644 gmic-qt/COPYING "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
-}
-
-package_krita-plugin-gmic() {
- pkgdesc="Krita plugin for the G'MIC image processing framework"
- depends=(krita)
-
- install -Dm755 gmic/gmic-qt/gmic_krita_qt -t "$pkgdir"/usr/bin/
-}
Copied: gmic/repos/community-x86_64/PKGBUILD (from rev 344309, gmic/trunk/PKGBUILD)
===================================================================
--- PKGBUILD (rev 0)
+++ PKGBUILD 2018-06-21 15:03:03 UTC (rev 344310)
@@ -0,0 +1,79 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Contributor: Jan "heftig" Steffens <jan.steffens at gmail.com>
+# Contributor: farid <farid at archlinuc-br.org>
+# Contributor: Archie <Mymaud at gmail.com>
+
+pkgbase=gmic
+pkgname=(gmic zart gimp-plugin-gmic krita-plugin-gmic)
+pkgver=2.3.0
+pkgrel=1
+arch=(x86_64)
+url="http://gmic.eu/"
+license=(custom:CeCILL)
+makedepends=(gimp qt5-base fftw openexr opencv git)
+source=(https://gmic.eu/files/source/gmic_$pkgver.tar.gz zart-qt5.11.patch)
+sha256sums=('8864abe38aaa65520a0992ee9b3f2c1d3bece5fd8ce069e93c7567f452efc375'
+ '92c7c98ccfd92d824e13d52db6136877a7ff483a411fed0d28f7e96474ab9c1b')
+
+prepare() {
+ sed -e 's|/etc/bash_completion.d|/usr/share/bash-completion/completions|g' -i gmic-$pkgver/src/Makefile
+ sed -e 's|-Ofast|-O2 -fno-fast-math|g' -i gmic-$pkgver/gmic-qt/gmic_qt.pro
+# fix overlinking
+ sed -e 's/pkg-config opencv --libs ||//' -e 's/-lopencv_highgui/-lopencv_videoio/' -i gmic-$pkgver/src/Makefile
+
+ cd gmic-$pkgver/zart
+ patch -p1 -i ../../zart-qt5.11.patch # Fix build with Qt 5.11
+}
+
+build() {
+ cd gmic-$pkgver
+ make -C src cli lib libc WGET=/bin/true
+
+ cd gmic-qt
+ qmake GMIC_PATH=../src GMIC_DYNAMIC_LINKING=on HOST=none
+ make
+ qmake GMIC_PATH=../src GMIC_DYNAMIC_LINKING=on HOST=gimp
+ make
+ qmake GMIC_PATH=../src GMIC_DYNAMIC_LINKING=on HOST=krita
+ make
+
+ cd ../zart
+ qmake GMIC_PATH=../src GMIC_DYNAMIC_LINKING=on
+ make
+}
+
+package_gmic() {
+ pkgdesc="GREYC's Magic Image Converter: image processing framework"
+ depends=(opencv fftw curl)
+ optdepends=('qt5-base: for the Qt UI')
+
+ cd gmic-$pkgver/src
+ make DESTDIR="$pkgdir" install
+ install -Dm644 ../COPYING "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+ rm -r "$pkgdir"/usr/{bin/zart,lib/gimp,bin/gmic_krita_qt}
+}
+
+package_zart() {
+ pkgdesc="A GUI for G'MIC real-time manipulations on the output of a webcam"
+ depends=(gmic qt5-base)
+
+ install -Dm755 gmic-$pkgver/zart/zart -t "$pkgdir"/usr/bin
+ install -Dm644 gmic-$pkgver/zart/Licence_CeCILL_V2-en.html -t "$pkgdir"/usr/share/licenses/$pkgname
+}
+
+package_gimp-plugin-gmic() {
+ pkgdesc="Gimp plugin for the G'MIC image processing framework"
+ depends=(gimp gmic qt5-base)
+
+ install -Dm755 gmic-$pkgver/gmic-qt/gmic_gimp_qt "$pkgdir"/usr/lib/gimp/2.0/plug-ins/gmic_gimp
+ install -Dm644 gmic-$pkgver/COPYING "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_krita-plugin-gmic() {
+ pkgdesc="Krita plugin for the G'MIC image processing framework"
+ depends=(krita gmic)
+
+ install -Dm755 gmic-$pkgver/gmic-qt/gmic_krita_qt -t "$pkgdir"/usr/bin/
+ install -Dm644 gmic-$pkgver/COPYING "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
Copied: gmic/repos/community-x86_64/zart-qt5.11.patch (from rev 344309, gmic/trunk/zart-qt5.11.patch)
===================================================================
--- zart-qt5.11.patch (rev 0)
+++ zart-qt5.11.patch 2018-06-21 15:03:03 UTC (rev 344310)
@@ -0,0 +1,22 @@
+From 148a3d755905eaaa00b580677376e30ca159c033 Mon Sep 17 00:00:00 2001
+From: Antonio Rojas <arojas at archlinux.org>
+Date: Thu, 21 Jun 2018 16:15:06 +0200
+Subject: [PATCH] Fix build with Qt 5.11
+
+Add missing QButtonGroup include
+---
+ src/MainWindow.cpp | 1 +
+ 1 file changed, 1 insertion(+)
+
+diff --git a/src/MainWindow.cpp b/src/MainWindow.cpp
+index c4e6590..638b887 100644
+--- a/src/MainWindow.cpp
++++ b/src/MainWindow.cpp
+@@ -47,6 +47,7 @@
+
+ #include <QAction>
+ #include <QActionGroup>
++#include <QButtonGroup>
+ #include <QComboBox>
+ #include <QDesktopServices>
+ #include <QDir>
More information about the arch-commits
mailing list