[arch-commits] Commit in mailutils/repos (3 files)

[Evangelos Foutras]

    Date: Thursday, June 28, 2018 @ 21:17:19
  Author: foutrelis
Revision: 347694

archrelease: copy trunk to community-staging-x86_64

Added:
  mailutils/repos/community-staging-x86_64/
  mailutils/repos/community-staging-x86_64/PKGBUILD
    (from rev 347693, mailutils/trunk/PKGBUILD)
  mailutils/repos/community-staging-x86_64/fix-build-mb-len-max.patch
    (from rev 347693, mailutils/trunk/fix-build-mb-len-max.patch)

----------------------------+
 PKGBUILD                   |   49 +++++++++++++++++++++++++++++++++++++++++++
 fix-build-mb-len-max.patch |   14 ++++++++++++
 2 files changed, 63 insertions(+)

Copied: mailutils/repos/community-staging-x86_64/PKGBUILD (from rev 347693, mailutils/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-06-28 21:17:19 UTC (rev 347694)
@@ -0,0 +1,49 @@
+# $Id$
+# Maintainer: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Contributor: Sergej Pupykin <pupykin.s+arch at gmail.com>
+
+pkgname=mailutils
+pkgver=3.4
+pkgrel=3
+pkgdesc="MUA command line tool (mailx)"
+arch=(x86_64)
+url="http://www.gnu.org/software/mailutils/"
+license=('GPL')
+depends=('libldap' 'pam' 'gnutls' 'gsasl')
+makedepends=('emacs')
+options=(!emptydirs)
+validpgpkeys=('325F650C4C2B6AD58807327A3602B07F55D0C732')
+source=(https://ftp.gnu.org/gnu/mailutils/mailutils-$pkgver.tar.bz2{,.sig}
+        fix-build-mb-len-max.patch)
+sha512sums=('3c674f272bf7275bd781f7069d859dc133d3f103a433a407736df7aecf31a5b0912bd3ebfa4a41095449219f2fdcf6277b6722e9e45dd14f8e26cc7270f863d7'
+            'SKIP'
+            '48248bfae1cc3b80c3decfcb99f803b65fd0d068f6c09625eb5e3763b3184090d7bd97fa3bc916b3e2e8c737b2bd501aa25482a96aceb555c08307b54c2a24a8')
+
+prepare() {
+  cd "$srcdir/mailutils-$pkgver"
+  # Include limits.h in frm/frm.h so it doesn't misdefine MB_LEN_MAX to 4
+  # (patch from github.com/NixOS/nixpkgs)
+  patch -Np1 -i ../fix-build-mb-len-max.patch
+}
+
+build() {
+  cd "$srcdir/mailutils-$pkgver"
+  ./configure \
+	--prefix=/usr \
+	--sbindir=/usr/bin \
+	--libexecdir=/usr/lib/$pkgname \
+	--with-gdbm \
+	--with-gnutls \
+	--disable-python \
+	--without-guile
+  make CFLAGS="$CFLAGS -O2" || make CFLAGS="$CFLAGS -O2" LDFLAGS="-L`pwd`/lib -lmutcpwrap -ltinfo"
+}
+
+package() {
+  cd "$srcdir/mailutils-$pkgver"
+  make -j1 DESTDIR="$pkgdir" install
+  rm -f "$pkgdir"/usr/share/info/dir
+  mv "$pkgdir"/usr/bin/mail "$pkgdir"/usr/bin/gnu-mail
+  mv "$pkgdir"/usr/share/man/man1/mail.1 "$pkgdir"/usr/share/man/man1/gnu-mail.1
+  chown -R root:root "$pkgdir"
+}

Copied: mailutils/repos/community-staging-x86_64/fix-build-mb-len-max.patch (from rev 347693, mailutils/trunk/fix-build-mb-len-max.patch)
===================================================================
--- community-staging-x86_64/fix-build-mb-len-max.patch	                        (rev 0)
+++ community-staging-x86_64/fix-build-mb-len-max.patch	2018-06-28 21:17:19 UTC (rev 347694)
@@ -0,0 +1,14 @@
+diff --git a/frm/frm.h b/frm/frm.h
+index 178b87d54..7931faada 100644
+--- a/frm/frm.h
++++ b/frm/frm.h
+@@ -34,6 +34,9 @@
+ #ifdef HAVE_ICONV_H
+ # include <iconv.h>
+ #endif
++#ifdef HAVE_LIMITS_H
++# include <limits.h>
++#endif
+ #ifndef MB_LEN_MAX
+ # define MB_LEN_MAX 4
+ #endif