[arch-commits] Commit in python-pluggy/repos (2 files)

[Felix Yan]

    Date: Saturday, June 30, 2018 @ 01:28:52
  Author: felixonmars
Revision: 347802

archrelease: copy trunk to community-staging-any

Added:
  python-pluggy/repos/community-staging-any/
  python-pluggy/repos/community-staging-any/PKGBUILD
    (from rev 347801, python-pluggy/trunk/PKGBUILD)

----------+
 PKGBUILD |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

Copied: python-pluggy/repos/community-staging-any/PKGBUILD (from rev 347801, python-pluggy/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2018-06-30 01:28:52 UTC (rev 347802)
@@ -0,0 +1,53 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-pluggy
+pkgname=(python-pluggy python2-pluggy)
+pkgver=0.6.0
+pkgrel=3
+pkgdesc="Plugin and hook calling mechanisms for python"
+arch=('any')
+url="https://www.pluggypayments.com/docs/python"
+license=('MIT')
+makedepends=('python-setuptools' 'python2-setuptools')
+checkdepends=('python-pytest-runner' 'python2-pytest-runner')
+source=("$pkgbase-$pkgver.tar.gz::https://github.com/pytest-dev/pluggy/archive/$pkgver.tar.gz")
+sha512sums=('ed8fe81907c7dc476ebfbf0f7e0f902577323d64014765e7d7bfe22c2dc7e4977e1ce7ad55ce7f4e923ae23d206d6c3bcc6663de760c877fce82298cc21079db')
+
+prepare() {
+  cp -a pluggy-$pkgver{,-py2}
+}
+
+build() {
+  cd "$srcdir"/pluggy-$pkgver
+  python setup.py build
+
+  cd "$srcdir"/pluggy-$pkgver-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/pluggy-$pkgver
+  python setup.py pytest
+
+  cd "$srcdir"/pluggy-$pkgver-py2
+  python2 setup.py pytest
+}
+
+package_python-pluggy() {
+  depends=('python')
+
+  cd pluggy-$pkgver
+  python setup.py install -O1 --root "$pkgdir"
+
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-pluggy() {
+  depends=('python2')
+
+  cd pluggy-$pkgver-py2
+  python2 setup.py install -O1 --root "$pkgdir"
+
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}