[arch-commits] Commit in python-mimeparse/repos (2 files)

[Felix Yan]

    Date: Saturday, June 30, 2018 @ 02:19:42
  Author: felixonmars
Revision: 347850

archrelease: copy trunk to community-staging-any

Added:
  python-mimeparse/repos/community-staging-any/
  python-mimeparse/repos/community-staging-any/PKGBUILD
    (from rev 347849, python-mimeparse/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: python-mimeparse/repos/community-staging-any/PKGBUILD (from rev 347849, python-mimeparse/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2018-06-30 02:19:42 UTC (rev 347850)
@@ -0,0 +1,50 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-mimeparse
+pkgname=(python-mimeparse python2-mimeparse)
+pkgver=1.6.0
+pkgrel=3
+pkgdesc='Module of basic functions for parsing mime-type names and matching them against a list of media-ranges'
+arch=('any')
+url="https://github.com/dbtsai/python-mimeparse"
+license=('MIT')
+makedepends=('python-setuptools' 'python2-setuptools' 'git')
+source=("git+https://github.com/dbtsai/python-mimeparse#tag=$pkgver")
+sha512sums=('SKIP')
+
+prepare() {
+  cp -a python-mimeparse{,-py2}
+}
+
+build() {
+  cd "$srcdir"/python-mimeparse
+  python setup.py build
+
+  cd "$srcdir"/python-mimeparse-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/python-mimeparse
+  python mimeparse_test.py
+
+  cd "$srcdir"/python-mimeparse-py2
+  python2 mimeparse_test.py
+}
+
+package_python-mimeparse() {
+  depends=('python')
+
+  cd python-mimeparse
+  python setup.py install -O1 --root "$pkgdir"
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-mimeparse() {
+  depends=('python2')
+
+  cd python-mimeparse-py2
+  python2 setup.py install -O1 --root "$pkgdir"
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}