[arch-commits] Commit in python-colorama/repos (2 files)
Felix Yan
felixonmars at archlinux.org
Sat Jun 30 03:28:25 UTC 2018
Date: Saturday, June 30, 2018 @ 03:28:24
Author: felixonmars
Revision: 347890
archrelease: copy trunk to community-staging-any
Added:
python-colorama/repos/community-staging-any/
python-colorama/repos/community-staging-any/PKGBUILD
(from rev 347889, python-colorama/trunk/PKGBUILD)
----------+
PKGBUILD | 56 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 56 insertions(+)
Copied: python-colorama/repos/community-staging-any/PKGBUILD (from rev 347889, python-colorama/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD (rev 0)
+++ community-staging-any/PKGBUILD 2018-06-30 03:28:24 UTC (rev 347890)
@@ -0,0 +1,56 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Alexander Duscheleit <jinks at archlinux.us>
+
+pkgbase=python-colorama
+pkgname=('python-colorama' 'python2-colorama')
+pkgver=0.3.9
+pkgrel=2
+pkgdesc="Python API for cross-platform colored terminal text."
+arch=('any')
+url="http://pypi.python.org/pypi/colorama"
+license=('BSD')
+makedepends=('python-setuptools' 'python2-setuptools')
+checkdepends=('python-mock' 'python2-mock')
+source=("$pkgbase-$pkgver.tar.gz::https://github.com/tartley/colorama/archive/$pkgver.tar.gz")
+sha512sums=('7bf6ec19181431d91f5c7a5334d01f9934d4555004e985f82ad74fc325c465339a4c3fdf017af6e0682e0b22e2bf78938cd222b670e5035f305d2d616b03d1d1')
+
+prepare() {
+ cp -a colorama-$pkgver{,-py2}
+}
+
+build() {
+ cd "$srcdir"/colorama-$pkgver
+ python setup.py build
+
+ cd "$srcdir"/colorama-$pkgver-py2
+ python2 setup.py build
+}
+
+check() {
+ cd "$srcdir"/colorama-$pkgver
+ python -m unittest discover -p *_test.py || warning "Tests failed"
+
+ cd "$srcdir"/colorama-$pkgver-py2
+ python2 -m unittest discover -p *_test.py || warning "Tests failed"
+}
+
+package_python-colorama() {
+ depends=('python')
+
+ cd colorama-$pkgver
+ python setup.py install --root="$pkgdir" --optimize=1
+
+ install -Dm644 LICENSE.txt "$pkgdir"/usr/share/licenses/$pkgname/LICENSE.txt
+}
+
+package_python2-colorama() {
+ depends=('python2')
+
+ cd colorama-$pkgver-py2
+ python2 setup.py install --root="$pkgdir" --optimize=1
+
+ install -Dm644 LICENSE.txt "$pkgdir"/usr/share/licenses/$pkgname/LICENSE.txt
+}
+
+# vim:set ts=2 sw=2 et:
More information about the arch-commits
mailing list