[arch-commits] Commit in python-yaml/repos (2 files)
Felix Yan
felixonmars at archlinux.org
Sat Jun 30 09:08:41 UTC 2018
Date: Saturday, June 30, 2018 @ 09:08:41
Author: felixonmars
Revision: 347998
archrelease: copy trunk to community-staging-x86_64
Added:
python-yaml/repos/community-staging-x86_64/
python-yaml/repos/community-staging-x86_64/PKGBUILD
(from rev 347997, python-yaml/trunk/PKGBUILD)
----------+
PKGBUILD | 64 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 64 insertions(+)
Copied: python-yaml/repos/community-staging-x86_64/PKGBUILD (from rev 347997, python-yaml/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD (rev 0)
+++ community-staging-x86_64/PKGBUILD 2018-06-30 09:08:41 UTC (rev 347998)
@@ -0,0 +1,64 @@
+# Maintainer: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Michal Bozon <michal.bozon__at__gmail.com>
+
+pkgbase=python-yaml
+pkgname=(python-yaml python2-yaml)
+pkgver=3.12
+pkgrel=4
+pkgdesc='Python bindings for YAML, using fast libYAML library'
+url='http://pyyaml.org/wiki/PyYAML'
+arch=('x86_64')
+license=('MIT')
+makedepends=('python' 'python2' 'libyaml' 'cython' 'cython2')
+source=(http://pyyaml.org/download/pyyaml/PyYAML-${pkgver}.tar.gz)
+sha512sums=('e16d8b7f4f026b6a95b11fb59c54ec5f114f6f516294eaa95e718abdf5d37c17a9c4b5e0a0a61fca04e801792d9b7fb801087cf849ff22b9581f6af204b1883a')
+
+prepare() {
+ # Force cython rebuild
+ rm PyYAML-$pkgver/ext/_yaml.c
+
+ cp -a PyYAML-$pkgver{,-py2}
+}
+
+build() {
+ msg2 "Building python..."
+ (cd PyYAML-$pkgver
+ python setup.py --with-libyaml build
+ )
+ msg2 "Building python2..."
+ (cd PyYAML-$pkgver-py2
+ python2 setup.py --with-libyaml build
+ )
+}
+
+check() {
+ msg2 "Checking python..."
+ (cd PyYAML-$pkgver
+ python setup.py test
+ )
+ msg2 "Checking python2..."
+ (cd PyYAML-$pkgver-py2
+ python2 setup.py test
+ )
+}
+
+package_python-yaml() {
+ depends=('python' 'libyaml')
+
+ cd PyYAML-$pkgver
+ python setup.py --with-libyaml install --prefix=/usr --root="${pkgdir}" -O1 --skip-build
+ install -Dm 644 LICENSE -t "${pkgdir}"/usr/share/licenses/${pkgname}
+ install -Dm 644 CHANGES README -t "${pkgdir}"/usr/share/doc/${pkgname}
+}
+
+package_python2-yaml() {
+ depends=('python2' 'libyaml')
+
+ cd PyYAML-$pkgver-py2
+ python2 setup.py --with-libyaml install --prefix=/usr --root="${pkgdir}" -O1 --skip-build
+ install -Dm 644 LICENSE -t "${pkgdir}"/usr/share/licenses/${pkgname}
+ install -Dm 644 CHANGES README -t "${pkgdir}"/usr/share/doc/${pkgname}
+}
+
+# vim: ts=2 sw=2 et:
More information about the arch-commits
mailing list