[arch-commits] Commit in python-pillow/repos (2 files)
Felix Yan
felixonmars at archlinux.org
Sat Jun 30 13:01:52 UTC 2018
Date: Saturday, June 30, 2018 @ 13:01:51
Author: felixonmars
Revision: 348069
archrelease: copy trunk to community-staging-x86_64
Added:
python-pillow/repos/community-staging-x86_64/
python-pillow/repos/community-staging-x86_64/PKGBUILD
(from rev 348063, python-pillow/trunk/PKGBUILD)
----------+
PKGBUILD | 79 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 79 insertions(+)
Copied: python-pillow/repos/community-staging-x86_64/PKGBUILD (from rev 348063, python-pillow/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD (rev 0)
+++ community-staging-x86_64/PKGBUILD 2018-06-30 13:01:51 UTC (rev 348069)
@@ -0,0 +1,79 @@
+# $Id$
+# Maintainer: Kyle Keen <keenerd at gmail.com>
+# Contributor: minder
+
+pkgbase=python-pillow
+pkgname=(python-pillow python2-pillow)
+pkgver=5.1.0
+pkgrel=2
+_appname=Pillow
+_py2basever=2.7
+_py3basever=3.7m
+pkgdesc="Python Imaging Library (PIL) fork. Python3 version."
+arch=('x86_64')
+url="https://python-pillow.github.io/"
+license=('BSD')
+depends=('lcms2' 'libtiff' 'openjpeg2')
+optdepends=('freetype2: for the ImageFont module'
+ 'libraqm: for complex text scripts'
+ 'libwebp: for webp images'
+ 'tk: for the ImageTK module')
+makedepends=('python-setuptools' 'python2-setuptools' 'freetype2' 'libraqm' 'libwebp' 'tk')
+checkdepends=('python-pytest' 'python2-pytest')
+source=("https://files.pythonhosted.org/packages/source/P/$_appname/$_appname-$pkgver.tar.gz")
+md5sums=('308f9c13b376abce96ab6ebd6c889cc4')
+
+# future optional things:
+# libimagequant
+
+prepare() {
+ cd "$srcdir/${_appname}-$pkgver"
+}
+
+build() {
+ cd "$srcdir/${_appname}-$pkgver"
+ python setup.py build
+ python2 setup.py build
+}
+
+check() {
+ cd "$srcdir/${_appname}-$pkgver"
+
+ export PYTHONPATH="$PWD/build/lib.linux-$CARCH-${_py3basever%m}"
+ python selftest.py
+ pytest
+ export PYTHONPATH="$PWD/build/lib.linux-$CARCH-$_py2basever"
+ python2 selftest.py
+ pytest2
+}
+
+package_python-pillow() {
+ depends+=('python')
+ optdepends+=('python-olefile: OLE2 file support'
+ 'python-pyqt4: for the ImageQt module'
+ 'python-pyqt5: for the ImageQt module'
+ 'python-pyside: for the ImageQt module')
+ cd "$srcdir/$_appname-$pkgver"
+ python3 setup.py install --root="$pkgdir/" --optimize=1
+ install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+
+ install -dm755 "$pkgdir/usr/include/python$_py3basever/"
+ install -m644 -t "$pkgdir/usr/include/python$_py3basever/" src/libImaging/*.h
+}
+
+package_python2-pillow() {
+ pkgdesc="Python Imaging Library (PIL) fork. Python2 version."
+ depends+=('python2')
+ optdepends+=('python2-olefile: OLE2 file support'
+ 'python2-pyqt5: for the ImageQt module'
+ 'python2-pyqt4: for the ImageQt module'
+ 'python2-pyside: for the ImageQt module')
+ provides=('python-imaging' 'python2-imaging')
+ conflicts=('python-imaging' 'python2-imaging')
+ cd "$srcdir/${_appname}-$pkgver"
+ python2 setup.py install --root="$pkgdir/" --optimize=1
+ install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+
+ install -dm755 "$pkgdir/usr/include/python$_py2basever/"
+ install -m644 -t "$pkgdir/usr/include/python$_py2basever/" src/libImaging/*.h
+}
More information about the arch-commits
mailing list