[arch-commits] Commit in python-olefile/repos (2 files)

[Felix Yan]

    Date: Saturday, June 30, 2018 @ 17:55:20
  Author: felixonmars
Revision: 348762

archrelease: copy trunk to community-staging-any

Added:
  python-olefile/repos/community-staging-any/
  python-olefile/repos/community-staging-any/PKGBUILD
    (from rev 348761, python-olefile/trunk/PKGBUILD)

----------+
 PKGBUILD |   60 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)

Copied: python-olefile/repos/community-staging-any/PKGBUILD (from rev 348761, python-olefile/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2018-06-30 17:55:20 UTC (rev 348762)
@@ -0,0 +1,60 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+
+pkgbase=python-olefile
+pkgname=('python-olefile' 'python2-olefile')
+_pyname=olefile
+pkgver=0.45.1
+pkgrel=2
+pkgdesc='Python library to parse, read and write Microsoft OLE2 files (formerly OleFileIO_PL)'
+url='http://www.decalage.info/olefile'
+arch=('any')
+license=('BSD')
+makedepends=('python' 'python2')
+checkdepends=('python-pytest' 'python2-pytest')
+source=(${_pyname}-${pkgver}.tar.gz::https://github.com/decalage2/olefile/archive/v${pkgver}.tar.gz)
+sha512sums=('72d40056cac1d9566aa8e32b7b5484f61958a689130e71fa86bc0b9fed98f27a8cf34b824971357d42ec3dfd2d5bfa86d0f212727ff91d8daa3967969ff576e9')
+
+prepare() {
+  cp -ra ${_pyname}-${pkgver}{,-py2}
+}
+
+build() {
+  (cd ${_pyname}-${pkgver}
+    python setup.py build
+  )
+  (cd ${_pyname}-${pkgver}-py2
+    python2 setup.py build
+  )
+}
+
+check() {
+  (cd ${_pyname}-${pkgver}
+    py.test
+  )
+  (cd ${_pyname}-${pkgver}-py2
+    py.test2
+  )
+}
+
+package_python-olefile() {
+  depends=('python')
+  replaces=('python3-olefileio')
+  conflicts=('python3-olefileio')
+  cd ${_pyname}-${pkgver}
+  python setup.py install -O1 --root="${pkgdir}" --prefix=/usr --skip-build
+  install -Dm 644 LICENSE.txt -t "${pkgdir}/usr/share/licenses/${pkgname}"
+  install -Dm 644 README.md doc/*.rst -t "${pkgdir}/usr/share/doc/${pkgname}"
+
+}
+
+package_python2-olefile() {
+  depends=('python2')
+  replaces=('python2-olefileio')
+  conflicts=('python2-olefileio')
+  cd ${_pyname}-${pkgver}-py2
+  python2 setup.py install -O1 --root="${pkgdir}" --prefix=/usr --skip-build
+  install -Dm 644 LICENSE.txt -t "${pkgdir}/usr/share/licenses/${pkgname}"
+  install -Dm 644 README.md doc/*.rst -t "${pkgdir}/usr/share/doc/${pkgname}"
+}
+
+# vim: ts=2 sw=2 et: