[arch-commits] Commit in python-websocket-client/repos (2 files)
Felix Yan
felixonmars at archlinux.org
Sat Jun 30 18:06:35 UTC 2018
Date: Saturday, June 30, 2018 @ 18:06:35
Author: felixonmars
Revision: 348852
archrelease: copy trunk to community-staging-any
Added:
python-websocket-client/repos/community-staging-any/
python-websocket-client/repos/community-staging-any/PKGBUILD
(from rev 348851, python-websocket-client/trunk/PKGBUILD)
----------+
PKGBUILD | 60 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 60 insertions(+)
Copied: python-websocket-client/repos/community-staging-any/PKGBUILD (from rev 348851, python-websocket-client/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD (rev 0)
+++ community-staging-any/PKGBUILD 2018-06-30 18:06:35 UTC (rev 348852)
@@ -0,0 +1,60 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Matmas <matmas at matmas.net>
+# Contributor: Thomas Gubler <thomasgubler at gmail.com>
+# Contributor: Daniel YC Lin <dlin.tw at gmail>
+# Contributor: Florian Bruhin <archlinux.org at the-compiler.org>
+
+pkgname=(python-websocket-client python2-websocket-client)
+pkgver=0.48.0
+pkgrel=2
+pkgdesc="WebSocket client library for Python"
+arch=(any)
+url="https://github.com/liris/websocket-client"
+license=('LGPL')
+makedepends=('python-setuptools' 'python2-setuptools' 'python-six' 'python2-six')
+source=(https://pypi.io/packages/source/w/websocket-client/websocket_client-$pkgver.tar.gz)
+sha512sums=('6c678a2671ce6cfb86a61effa836bbe4bb1702f22827934b1fcd7f0f8439be76037d9b6d4d6b416249361a9a74a92701d7b90bc6276b2433388644ed66f56333')
+
+prepare() {
+ # Not sure why the conditions are not working :/
+ sed -i "s/'backports.ssl_match_hostname'//" websocket_client-$pkgver/setup.py
+
+ cp -a websocket_client-$pkgver{,-py2}
+}
+
+build() {
+ cd "$srcdir"/websocket_client-$pkgver
+ python setup.py build
+
+ cd "$srcdir"/websocket_client-$pkgver-py2
+ python2 setup.py build
+}
+
+check() {
+ cd "$srcdir"/websocket_client-$pkgver
+ python setup.py test
+
+ cd "$srcdir"/websocket_client-$pkgver-py2
+ python2 setup.py test
+}
+
+package_python-websocket-client() {
+ depends=('python-six')
+
+ cd websocket_client-$pkgver
+ python setup.py install --root="$pkgdir" --optimize=1
+ install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-websocket-client() {
+ depends=('python2-six')
+
+ cd websocket_client-$pkgver-py2
+ python2 setup.py install --root="$pkgdir" --optimize=1
+ install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+
+ mv "$pkgdir"/usr/bin/wsdump{,2}.py
+}
+
+# vim:set ts=2 sw=2 ft=sh et:
More information about the arch-commits
mailing list