[arch-commits] Commit in python-geoip/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Felix Yan]

    Date: Saturday, June 30, 2018 @ 18:11:59
  Author: felixonmars
Revision: 327880

archrelease: copy trunk to staging-x86_64

Added:
  python-geoip/repos/staging-x86_64/
  python-geoip/repos/staging-x86_64/PKGBUILD
    (from rev 327879, python-geoip/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: python-geoip/repos/staging-x86_64/PKGBUILD (from rev 327879, python-geoip/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2018-06-30 18:11:59 UTC (rev 327880)
@@ -0,0 +1,44 @@
+# $Id$
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+# Contributor: Angel Velasquez <angvp at archlinux.org>
+
+pkgbase=python-geoip
+pkgname=('python-geoip' 'python2-geoip')
+pkgver=1.3.2
+pkgrel=5
+pkgdesc="Python bindings for the GeoIP IP-to-country resolver library"
+arch=('x86_64')
+url="https://pypi.python.org/pypi/GeoIP/"
+license=('LGPL')
+makedepends=('python' 'python2' 'geoip')
+source=(https://pypi.python.org/packages/source/G/GeoIP/GeoIP-${pkgver}.tar.gz)
+md5sums=('6d1a82798b9f5f8448fca50296d974ba')
+
+prepare() {
+  cp -a "GeoIP-$pkgver"{,-py2}
+}
+
+build() {
+  cd "GeoIP-$pkgver"
+  python setup.py build
+
+  cd "../GeoIP-$pkgver-py2"
+  python2 setup.py build
+}
+
+package_python-geoip() {
+  depends=('python' 'geoip')
+
+  cd "GeoIP-$pkgver"
+  python setup.py install --root="$pkgdir" -O1
+}
+
+package_python2-geoip() {
+  depends=('python2' 'geoip')
+  conflicts=('python-geoip<1.2.8')
+
+  cd "GeoIP-$pkgver-py2"
+  python2 setup.py install --root="$pkgdir" -O1
+}
+
+# vim:set ts=2 sw=2 et: