[arch-commits] Commit in lib32-pango/repos/multilib-x86_64 (PKGBUILD PKGBUILD)

[Jan Steffens]

    Date: Thursday, March 1, 2018 @ 16:53:19
  Author: heftig
Revision: 301013

archrelease: copy trunk to multilib-x86_64

Added:
  lib32-pango/repos/multilib-x86_64/PKGBUILD
    (from rev 301012, lib32-pango/trunk/PKGBUILD)
Deleted:
  lib32-pango/repos/multilib-x86_64/PKGBUILD

----------+
 PKGBUILD |  107 ++++++++++++++++++++++++++-----------------------------------
 1 file changed, 47 insertions(+), 60 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2018-03-01 16:52:17 UTC (rev 301012)
+++ PKGBUILD	2018-03-01 16:53:19 UTC (rev 301013)
@@ -1,60 +0,0 @@
-# $Id$
-# Contributor: Pierre Schmitz <pierre at archlinux.de>
-# Contributor: Mikko Seppälä <t-r-a-y at mbnet.fi>
-# Maintainer: Biru Ionut <ionut at archlinux.ro>
-
-_pkgbasename=pango
-pkgname=lib32-$_pkgbasename
-pkgver=1.40.6+9+g92cc73c8
-pkgrel=1
-pkgdesc="A library for layout and rendering of text (32-bit)"
-url="https://www.pango.org/"
-arch=(x86_64)
-license=(LGPL)
-depends=(lib32-libthai lib32-libgl lib32-cairo lib32-libxft
-         $_pkgbasename)
-makedepends=(gcc-multilib gobject-introspection meson git)
-options=('!emptydirs')
-_commit=92cc73c898e4665fd739704417d487d137dd271b  # master
-source=("git+https://git.gnome.org/browse/pango#commit=$_commit")
-sha256sums=('SKIP')
-
-pkgver() {
-  cd $_pkgbasename
-
-  git describe --tags | sed 's/-/+/g'
-}
- 
- prepare() {
-  cd $_pkgbasename
-
-  mkdir ../build
-  sed -i 's#"pango.modules"#"pango.modules-32"#' pango/modules.c
-}
-
-build() {
-  export CC="gcc -m32"
-  export CXX="g++ -m32"
-  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
-
-  cd build
-
-  meson --prefix=/usr --libdir=/usr/lib32 --libexecdir=/usr/lib32 \
-    --buildtype=release ../$_pkgbasename
-  ninja -v
-
-#   ./configure --prefix=/usr --libdir=/usr/lib32 --sysconfdir=/etc \
-#       --localstatedir=/var \
-#       --with-dynamic-modules=arabic-fc,arabic-lang,basic-fc,basic-win32,basic-x,basic-atsui,hangul-fc,hebrew-fc,indic-fc,indic-lang,khmer-fc,syriac-fc,tibetan-fc \
-#       --disable-introspection
-#   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
-#   make
-}
-
-package() {
-  cd build
-
-  DESTDIR="$pkgdir" ninja install
-  rm -rf "$pkgdir"/etc
-  rm -rf "$pkgdir"/usr/{bin/pango-view,share,include}
-}

Copied: lib32-pango/repos/multilib-x86_64/PKGBUILD (from rev 301012, lib32-pango/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2018-03-01 16:53:19 UTC (rev 301013)
@@ -0,0 +1,47 @@
+# $Id$
+# Contributor: Biru Ionut <ionut at archlinux.ro>
+# Contributor: Pierre Schmitz <pierre at archlinux.de>
+# Contributor: Mikko Seppälä <t-r-a-y at mbnet.fi>
+
+pkgname=lib32-pango
+pkgver=1.40.14
+pkgrel=1
+pkgdesc="A library for layout and rendering of text (32-bit)"
+url="https://www.pango.org/"
+arch=(x86_64)
+license=(LGPL)
+depends=(lib32-libthai lib32-cairo lib32-libxft lib32-harfbuzz pango)
+makedepends=(gcc-multilib gobject-introspection git meson)
+checkdepends=(ttf-dejavu cantarell-fonts)
+_commit=cd26b69cf0d45e30cb8c08ca5aa32ed0c83e6605  # tags/1.40.14^0
+source=("git+https://git.gnome.org/browse/pango#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd pango
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd pango
+  sed -i 's#"pango.modules"#"pango.modules-32"#' pango/modules.c
+}
+
+build() {
+  export CC="gcc -m32"
+  export CXX="g++ -m32"
+  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
+
+  arch-meson pango build --libdir=/usr/lib32
+  ninja -C build
+}
+
+check() {
+  cd build
+  meson test
+}
+
+package() {
+  DESTDIR="$pkgdir" ninja -C build install
+  rm -r "$pkgdir"/usr/{bin,lib,share,include}
+}