[arch-commits] Commit in gnome-keyring/repos (3 files)
Jan Steffens
heftig at archlinux.org
Thu Mar 8 20:52:15 UTC 2018
Date: Thursday, March 8, 2018 @ 20:52:14
Author: heftig
Revision: 318287
archrelease: copy trunk to gnome-unstable-x86_64
Added:
gnome-keyring/repos/gnome-unstable-x86_64/
gnome-keyring/repos/gnome-unstable-x86_64/PKGBUILD
(from rev 318286, gnome-keyring/trunk/PKGBUILD)
gnome-keyring/repos/gnome-unstable-x86_64/gnome-keyring.install
(from rev 318286, gnome-keyring/trunk/gnome-keyring.install)
-----------------------+
PKGBUILD | 55 ++++++++++++++++++++++++++++++++++++++++++++++++
gnome-keyring.install | 7 ++++++
2 files changed, 62 insertions(+)
Copied: gnome-keyring/repos/gnome-unstable-x86_64/PKGBUILD (from rev 318286, gnome-keyring/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD 2018-03-08 20:52:14 UTC (rev 318287)
@@ -0,0 +1,55 @@
+#$Id$
+# Maintainer: Jan De Groot <jgc at archlinux.org>
+
+pkgname=gnome-keyring
+pkgver=3.27.92+1+g7120f44c
+pkgrel=1
+epoch=1
+pkgdesc="Stores passwords and encryption keys"
+url="https://wiki.gnome.org/Projects/GnomeKeyring"
+arch=(x86_64)
+license=(GPL LGPL)
+depends=(gcr libcap-ng pam openssh)
+makedepends=(git docbook-xsl python)
+checkdepends=(python2)
+groups=(gnome)
+install=gnome-keyring.install
+_commit=7120f44ceedd5c10802781d64a5829b3c6d8e13f # master
+source=("git+https://git.gnome.org/browse/gnome-keyring#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+ cd $pkgname
+ git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+ cd $pkgname
+ sed -i 's/MATE/MATE;Cinnamon/' daemon/*.desktop.in.in
+ sed -i '1s/python$/&2/' build/tap-{driver,gtester}
+ autoreconf -fvi
+}
+
+build() {
+ cd $pkgname
+ ./configure --prefix=/usr \
+ --sysconfdir=/etc \
+ --localstatedir=/var \
+ --libexecdir=/usr/lib \
+ --with-pam-dir=/usr/lib/security \
+ --disable-static \
+ --disable-schemas-compile
+ sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+ make
+}
+
+check() {
+ cd $pkgname
+ # Secure memory tests fail
+ dbus-run-session make -k check || :
+}
+
+package() {
+ cd $pkgname
+ make DESTDIR="$pkgdir" install
+}
Copied: gnome-keyring/repos/gnome-unstable-x86_64/gnome-keyring.install (from rev 318286, gnome-keyring/trunk/gnome-keyring.install)
===================================================================
--- gnome-unstable-x86_64/gnome-keyring.install (rev 0)
+++ gnome-unstable-x86_64/gnome-keyring.install 2018-03-08 20:52:14 UTC (rev 318287)
@@ -0,0 +1,7 @@
+post_install() {
+ setcap cap_ipc_lock=ep usr/bin/gnome-keyring-daemon
+}
+
+post_upgrade() {
+ post_install
+}
More information about the arch-commits
mailing list