[arch-commits] Commit in haskell-dbus/repos (2 files)

Felix Yan felixonmars at archlinux.org
Sat Mar 10 06:44:11 UTC 2018


    Date: Saturday, March 10, 2018 @ 06:44:10
  Author: felixonmars
Revision: 305654

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-dbus/repos/community-staging-x86_64/
  haskell-dbus/repos/community-staging-x86_64/PKGBUILD
    (from rev 305653, haskell-dbus/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: haskell-dbus/repos/community-staging-x86_64/PKGBUILD (from rev 305653, haskell-dbus/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-03-10 06:44:10 UTC (rev 305654)
@@ -0,0 +1,45 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=dbus
+pkgname=haskell-dbus
+pkgver=0.10.15
+pkgrel=16
+pkgdesc="A client library for the D-Bus IPC system"
+url="https://john-millikin.com/software/haskell-dbus/"
+license=("GPL3")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-cereal' 'haskell-libxml-sax' 'haskell-network' 'haskell-parsec'
+         'haskell-random' 'haskell-text' 'haskell-vector' 'haskell-xml-types')
+makedepends=('ghc' 'haskell-extra' 'haskell-quickcheck' 'haskell-resourcet' 'haskell-tasty'
+             'haskell-tasty-hunit' 'haskell-tasty-quickcheck')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('5c81c1f8599b80cdb16bee63b97cd1aa5d6b0698095b2c366ad4e4f03b44f9166bd5d770f8a47a0c7dd746a9a734379dc20a77f7846a862bd1c213eb12559b0b')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/license.txt"
+}



More information about the arch-commits mailing list