[arch-commits] Commit in gst-plugins-good/repos (2 files)
Jan Steffens
heftig at archlinux.org
Sun Mar 11 03:25:08 UTC 2018
Date: Sunday, March 11, 2018 @ 03:25:07
Author: heftig
Revision: 318523
archrelease: copy trunk to gnome-unstable-x86_64
Added:
gst-plugins-good/repos/gnome-unstable-x86_64/
gst-plugins-good/repos/gnome-unstable-x86_64/PKGBUILD
(from rev 318522, gst-plugins-good/trunk/PKGBUILD)
----------+
PKGBUILD | 62 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 62 insertions(+)
Copied: gst-plugins-good/repos/gnome-unstable-x86_64/PKGBUILD (from rev 318522, gst-plugins-good/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD 2018-03-11 03:25:07 UTC (rev 318523)
@@ -0,0 +1,62 @@
+# $Id$
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+
+pkgname=gst-plugins-good
+pkgver=1.13.90+3+g13dd93aca
+pkgrel=1
+pkgdesc="GStreamer Multimedia Framework Good Plugins"
+url="https://gstreamer.freedesktop.org/"
+arch=(x86_64)
+license=(LGPL)
+depends=(libpulse jack libsoup gst-plugins-base-libs wavpack aalib taglib libdv libshout libvpx
+ gdk-pixbuf2 libcaca libavc1394 libiec61883 libxdamage v4l-utils cairo libgudev speex flac
+ libraw1394 lame mpg123 twolame)
+makedepends=(python gtk-doc autoconf-archive git gtk3 qt5-declarative qt5-x11extras qt5-wayland)
+checkdepends=(gst-plugins-base)
+_commit=13dd93aca1ff78d191aadea9fccd88ff859b8fbf # master
+source=("git+https://anongit.freedesktop.org/git/gstreamer/gst-plugins-good#commit=$_commit"
+ "gst-common::git+https://anongit.freedesktop.org/git/gstreamer/common")
+sha256sums=('SKIP'
+ 'SKIP')
+
+pkgver() {
+ cd $pkgname
+ git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+ cd $pkgname
+
+ git submodule init
+ git config --local submodule.common.url "$srcdir/gst-common"
+ git submodule update
+
+ NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+ cd $pkgname
+ ./configure \
+ --prefix=/usr \
+ --sysconfdir=/etc \
+ --localstatedir=/var \
+ --libexecdir=/usr/lib \
+ --with-package-name="GStreamer Good Plugins (Arch Linux)" \
+ --with-package-origin="https://www.archlinux.org/" \
+ --enable-experimental \
+ --enable-gtk-doc \
+ --disable-static
+ sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+ make
+}
+
+check() {
+ cd $pkgname
+ make check
+}
+
+package() {
+ cd $pkgname
+ make DESTDIR="$pkgdir" install
+}
More information about the arch-commits
mailing list