[arch-commits] Commit in gstreamer-vaapi/repos (2 files)

[Jan Steffens]

    Date: Sunday, March 11, 2018 @ 04:32:31
  Author: heftig
Revision: 318532

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  gstreamer-vaapi/repos/gnome-unstable-x86_64/
  gstreamer-vaapi/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 318531, gstreamer-vaapi/trunk/PKGBUILD)

----------+
 PKGBUILD |   55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

Copied: gstreamer-vaapi/repos/gnome-unstable-x86_64/PKGBUILD (from rev 318531, gstreamer-vaapi/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2018-03-11 04:32:31 UTC (rev 318532)
@@ -0,0 +1,55 @@
+# $Id$
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+
+pkgname=gstreamer-vaapi
+pkgver=1.13.90
+pkgrel=1
+pkgdesc="GStreamer Multimedia Framework VAAPI Plugin"
+url="https://gstreamer.freedesktop.org/"
+arch=(x86_64)
+license=(LGPL)
+depends=(gst-plugins-bad libva libxrandr)
+makedepends=(python gtk-doc autoconf-archive git gtk3)
+_commit=f6f981e371ba8b189174a0d8a18aac9c8ea6bfab  # tags/1.13.90^0
+source=("git+https://anongit.freedesktop.org/git/gstreamer/gstreamer-vaapi#commit=$_commit"
+        "gst-common::git+https://anongit.freedesktop.org/git/gstreamer/common")
+sha256sums=('SKIP'
+            'SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+
+  git submodule init
+  git config --local submodule.common.url "$srcdir/gst-common"
+  git submodule update
+
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+  ./configure \
+    --prefix=/usr \
+    --sysconfdir=/etc \
+    --localstatedir=/var \
+    --libexecdir=/usr/lib \
+    --enable-gtk-doc \
+    --disable-static
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+check() {
+  cd $pkgname
+  make check
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+}