[arch-commits] Commit in woff2/trunk (PKGBUILD)

[Jan Steffens]

    Date: Sunday, March 11, 2018 @ 17:33:03
  Author: heftig
Revision: 318557

1.0.2-1

Added:
  woff2/trunk/PKGBUILD

----------+
 PKGBUILD |   32 ++++++++++++++++++++++++++++++++
 1 file changed, 32 insertions(+)

Added: PKGBUILD
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2018-03-11 17:33:03 UTC (rev 318557)
@@ -0,0 +1,32 @@
+# $Id$
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+
+pkgname=woff2
+pkgver=1.0.2
+pkgrel=1
+pkgdesc="Web Open Font Format 2 reference implementation"
+url="https://github.com/google/woff2"
+arch=(x86_64)
+license=(custom:MIT)
+depends=(brotli)
+makedepends=(git cmake ninja)
+_commit=1bccf208bca986e53a647dfe4811322adb06ecf8  # tags/v1.0.2
+source=("git+$url#commit=$_commit")
+sha512sums=('SKIP')
+
+prepare() {
+  cd $pkgname
+  sed -i 's/NOT BUILD_SHARED_LIBS/TRUE/' CMakeLists.txt
+}
+
+build() {
+  cd $pkgname
+  cmake -G Ninja -DCMAKE_INSTALL_PREFIX=/usr -DCMAKE_INSTALL_LIBDIR=/usr/lib .
+  ninja
+}
+
+package() {
+  cd $pkgname
+  DESTDIR="$pkgdir" ninja install
+  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 LICENSE
+}


Property changes on: woff2/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property