[arch-commits] Commit in cheese/repos (2 files)

[Jan Steffens]

    Date: Sunday, March 11, 2018 @ 20:03:30
  Author: heftig
Revision: 318643

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  cheese/repos/gnome-unstable-x86_64/
  cheese/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 318642, cheese/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: cheese/repos/gnome-unstable-x86_64/PKGBUILD (from rev 318642, cheese/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2018-03-11 20:03:30 UTC (rev 318643)
@@ -0,0 +1,52 @@
+# $Id$
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+pkgname=cheese
+pkgver=3.26.0+22+g673ad8a0
+pkgrel=1
+pkgdesc="Take photos and videos with your webcam, with fun graphical effects"
+url="https://wiki.gnome.org/Apps/Cheese"
+arch=(x86_64)
+license=(GPL)
+depends=(gtk3 gstreamer gst-plugins-bad gst-plugins-base gst-plugins-good clutter-gst clutter-gtk
+         libcanberra librsvg gnome-desktop libgudev dconf)
+makedepends=(pkgconfig intltool gobject-introspection itstool vala gnome-common git appstream-glib
+             gnome-video-effects)
+optdepends=('gnome-video-effects: Camera effects')
+groups=(gnome)
+options=(!emptydirs)
+_commit=673ad8a03ca9d16caf3ccbcfa64bb9cb948bba2b  # master
+source=("git+https://git.gnome.org/browse/cheese#commit=$_commit")
+sha256sums=('SKIP')
+
+# TODO: Consider splitting libcheese
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  # Fixup tags for pkgver()
+  git tag -f 3.26.0 41843aad67d56918587543aec22ba15cfef25ebc
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
+      --disable-static --disable-schemas-compile --libexecdir=/usr/lib/cheese \
+      --enable-gtk-doc
+
+  # https://bugzilla.gnome.org/show_bug.cgi?id=655517
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+
+  make
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+}