[arch-commits] Commit in gnome-music/repos (2 files)
Bartłomiej Piotrowski
bpiotrowski at archlinux.org
Tue Mar 13 15:11:29 UTC 2018
Date: Tuesday, March 13, 2018 @ 15:11:28
Author: bpiotrowski
Revision: 318834
archrelease: copy trunk to gnome-unstable-x86_64
Added:
gnome-music/repos/gnome-unstable-x86_64/
gnome-music/repos/gnome-unstable-x86_64/PKGBUILD
(from rev 318833, gnome-music/trunk/PKGBUILD)
----------+
PKGBUILD | 45 +++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 45 insertions(+)
Copied: gnome-music/repos/gnome-unstable-x86_64/PKGBUILD (from rev 318833, gnome-music/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD 2018-03-13 15:11:28 UTC (rev 318834)
@@ -0,0 +1,45 @@
+# $Id$
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+
+pkgname=gnome-music
+pkgver=3.28.0
+pkgrel=1
+pkgdesc="Music player and management application"
+url="https://wiki.gnome.org/Apps/Music"
+arch=(x86_64)
+license=(GPL)
+depends=(grilo grilo-plugins tracker-miners libdmapsharing libmediaart gtk3 gvfs python-gobject
+ python-cairo gst-plugins-base python-requests)
+makedepends=(intltool itstool gobject-introspection gnome-common git meson)
+optdepends=('gst-plugins-good: Extra media codecs'
+ 'gst-plugins-ugly: Extra media codecs'
+ 'gst-plugins-bad: Extra media codecs'
+ 'gst-libav: Extra media codecs')
+groups=(gnome)
+_commit=27cf72d9fae8befd0b1583b6bd6dc4ca140c2e3c # tags/3.28.0^0
+source=("git+https://git.gnome.org/browse/gnome-music#commit=$_commit"
+ "git+https://git.gnome.org/browse/libgd")
+sha256sums=('SKIP'
+ 'SKIP')
+
+pkgver() {
+ cd $pkgname
+ git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+ cd $pkgname
+
+ git submodule init
+ git config --local submodule.libgd.url "$srcdir/libgd"
+ git submodule update
+}
+
+build() {
+ arch-meson $pkgname build
+ ninja -C build
+}
+
+package() {
+ DESTDIR="$pkgdir" ninja -C build install
+}
More information about the arch-commits
mailing list