[arch-commits] Commit in gedit/repos (2 files)

Bartłomiej Piotrowski bpiotrowski at archlinux.org
Tue Mar 13 21:30:20 UTC 2018


    Date: Tuesday, March 13, 2018 @ 21:30:19
  Author: bpiotrowski
Revision: 318897

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  gedit/repos/gnome-unstable-x86_64/
  gedit/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 318896, gedit/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: gedit/repos/gnome-unstable-x86_64/PKGBUILD (from rev 318896, gedit/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2018-03-13 21:30:19 UTC (rev 318897)
@@ -0,0 +1,50 @@
+# $Id$
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+pkgname=gedit
+pkgver=3.28.0
+pkgrel=1
+pkgdesc="GNOME Text Editor"
+url="https://wiki.gnome.org/Apps/Gedit"
+arch=(x86_64)
+license=(GPL)
+depends=(gtksourceview3 gsettings-desktop-schemas libpeas gspell python-gobject dconf)
+makedepends=(yelp-tools intltool vala gobject-introspection gnome-common git gtk-doc)
+optdepends=('gedit-plugins: Additional features')
+groups=(gnome)
+_commit=304fb24331a097764a0db160fc95fb1b978f4106  # tags/3.28.0^0
+source=("git+https://git.gnome.org/browse/gedit#commit=$_commit"
+        "git+https://git.gnome.org/browse/libgd")
+sha256sums=('SKIP'
+            'SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+
+  git submodule init
+  git config --local submodule.libgd.url "$srcdir/libgd"
+  git submodule update
+
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr \
+      --sysconfdir=/etc --localstatedir=/var \
+      --libexecdir=/usr/lib --disable-updater --disable-schemas-compile \
+      --enable-python --enable-gtk-doc
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+package(){
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+}



More information about the arch-commits mailing list