[arch-commits] Commit in gvfs/trunk (PKGBUILD)
Jan Steffens
heftig at archlinux.org
Tue Mar 13 22:07:11 UTC 2018
Date: Tuesday, March 13, 2018 @ 22:07:10
Author: heftig
Revision: 318908
1.36.0-1
Modified:
gvfs/trunk/PKGBUILD
----------+
PKGBUILD | 135 +++++++++++++++++++++++++++++++++----------------------------
1 file changed, 74 insertions(+), 61 deletions(-)
Modified: PKGBUILD
===================================================================
--- PKGBUILD 2018-03-13 22:03:09 UTC (rev 318907)
+++ PKGBUILD 2018-03-13 22:07:10 UTC (rev 318908)
@@ -3,7 +3,7 @@
pkgbase=gvfs
pkgname=(gvfs gvfs-{smb,afc,gphoto2,goa,mtp,nfs,google})
-pkgver=1.34.2.1
+pkgver=1.36.0
pkgrel=1
pkgdesc="Virtual filesystem implementation for GIO"
url="https://wiki.gnome.org/Projects/gvfs"
@@ -11,10 +11,10 @@
license=(LGPL)
depends=(avahi dconf fuse libarchive libcdio-paranoia libsoup udisks2 libsecret
libbluray libgudev gcr psmisc)
-makedepends=(dbus intltool libgphoto2 libimobiledevice smbclient docbook-xsl
- gtk3 libmtp gnome-online-accounts libnfs libgdata git gtk-doc python)
+makedepends=(dbus libgphoto2 libimobiledevice smbclient docbook-xsl gtk3 libmtp
+ gnome-online-accounts libnfs libgdata git gtk-doc python meson openssh)
groups=(gnome)
-_commit=d988206659abcdf36838276c24963128642b626c # tags/1.34.2.1^0
+_commit=1d67d10e5bc41749c02dbca8a6cb84f6840de5cd # tags/1.36.0^0
source=("git+https://git.gnome.org/browse/gvfs#commit=$_commit"
gvfsd.hook)
sha256sums=('SKIP'
@@ -22,7 +22,6 @@
prepare() {
cd $pkgbase
- NOCONFIGURE=1 ./autogen.sh
}
pkgver() {
@@ -31,14 +30,26 @@
}
build() {
- cd $pkgbase
- ./configure --prefix=/usr --sysconfdir=/etc \
- --localstatedir=/var --disable-static \
- --libexecdir=/usr/lib/gvfs
- sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
- make
+ arch-meson $pkgbase build -D man=true -D deprecated_programs=true
+ ninja -C build
}
+check() {
+ cd build
+ meson test
+}
+
+_split() {
+ local name="$1" src dest
+ shift
+ for src do
+ echo "$name: /usr/$src"
+ dest="$srcdir/$name/$src"
+ mkdir -p "${dest%/*}"
+ mv -T "$src" "$dest"
+ done
+}
+
package_gvfs() {
replaces=(gvfs-{obexftp,afp})
optdepends=('gvfs-afc: AFC (mobile devices) support'
@@ -49,23 +60,55 @@
'gvfs-nfs: NFS support'
'gvfs-google: Google Drive support'
'gtk3: Recent files support')
+ options=(!emptydirs)
- cd $pkgbase
- sed -e 's/^am__append_3/#am__append_3/' \
- -e 's/^am__append_4/#am__append_4/' \
- -e 's/^am__append_5/#am__append_5/' \
- -e 's/^am__append_6/#am__append_6/' \
- -i monitor/Makefile
- make DESTDIR="$pkgdir" install
+ DESTDIR="$pkgdir" ninja -C build install
- install -Dm644 ../gvfsd.hook "$pkgdir/usr/share/libalpm/hooks/gvfsd.hook"
+ install -Dt "$pkgdir/usr/share/libalpm/hooks" -m644 *.hook
install -d -o root -g 102 -m 750 "$pkgdir/usr/share/polkit-1/rules.d"
- cd "$pkgdir"
- rm usr/lib/gvfs/gvfsd-{smb,smb-browse,afc,gphoto2,mtp,nfs,google}
- rm usr/share/gvfs/mounts/{smb,smb-browse,afc,gphoto2,mtp,nfs,google}.mount
- rm usr/share/glib-2.0/schemas/org.gnome.system.smb.gschema.xml
- rm usr/share/GConf/gsettings/gvfs-smb.convert
+ cd "$pkgdir/usr"
+
+ _split smb \
+ lib/gvfsd-smb{,-browse} \
+ share/GConf/gsettings/gvfs-smb.convert \
+ share/glib-2.0/schemas/org.gnome.system.smb.gschema.xml \
+ share/gvfs/mounts/smb{,-browse}.mount
+
+ _split afc \
+ lib/gvfs{-afc-volume-monitor,d-afc} \
+ lib/systemd/user/gvfs-afc-volume-monitor.service \
+ share/dbus-1/services/org.gtk.vfs.AfcVolumeMonitor.service \
+ share/gvfs/mounts/afc.mount \
+ share/gvfs/remote-volume-monitors/afc.monitor
+
+ _split gphoto2 \
+ lib/gvfs{-gphoto2-volume-monitor,d-gphoto2} \
+ lib/systemd/user/gvfs-gphoto2-volume-monitor.service \
+ share/dbus-1/services/org.gtk.vfs.GPhoto2VolumeMonitor.service \
+ share/gvfs/mounts/gphoto2.mount \
+ share/gvfs/remote-volume-monitors/gphoto2.monitor
+
+ _split mtp \
+ lib/gvfs{-mtp-volume-monitor,d-mtp} \
+ lib/systemd/user/gvfs-mtp-volume-monitor.service \
+ share/dbus-1/services/org.gtk.vfs.MTPVolumeMonitor.service \
+ share/gvfs/mounts/mtp.mount \
+ share/gvfs/remote-volume-monitors/mtp.monitor
+
+ _split goa \
+ lib/gvfs-goa-volume-monitor \
+ lib/systemd/user/gvfs-goa-volume-monitor.service \
+ share/dbus-1/services/org.gtk.vfs.GoaVolumeMonitor.service \
+ share/gvfs/remote-volume-monitors/goa.monitor
+
+ _split nfs \
+ lib/gvfsd-nfs \
+ share/gvfs/mounts/nfs.mount
+
+ _split google \
+ lib/gvfsd-google \
+ share/gvfs/mounts/google.mount
}
package_gvfs-smb() {
@@ -72,17 +115,7 @@
pkgdesc+=" (SMB/CIFS backend; Windows client)"
depends=("gvfs=$pkgver" smbclient)
- cd $pkgbase/daemon
- install -m755 -d "$pkgdir/usr/lib/gvfs"
- install -m755 -d "$pkgdir/usr/share/gvfs/mounts"
-
- install -m755 .libs/gvfsd-smb{,-browse} "$pkgdir/usr/lib/gvfs/"
- install -m644 smb{,-browse}.mount "$pkgdir/usr/share/gvfs/mounts/"
-
- install -Dm644 org.gnome.system.smb.gschema.xml \
- "$pkgdir/usr/share/glib-2.0/schemas/org.gnome.system.smb.gschema.xml"
- install -Dm644 gvfs-smb.convert \
- "$pkgdir/usr/share/GConf/gsettings/gvfs-smb.convert"
+ mv "$srcdir/smb" "$pkgdir/usr"
}
package_gvfs-afc() {
@@ -89,12 +122,7 @@
pkgdesc+=" (AFC backend; Apple mobile devices)"
depends=("gvfs=$pkgver" libimobiledevice usbmuxd)
- cd $pkgbase/daemon
- install -D .libs/gvfsd-afc "$pkgdir/usr/lib/gvfs/gvfsd-afc"
- install -Dm644 afc.mount "$pkgdir/usr/share/gvfs/mounts/afc.mount"
-
- cd "$srcdir/$pkgbase/monitor/afc"
- make DESTDIR="$pkgdir" install
+ mv "$srcdir/afc" "$pkgdir/usr"
}
package_gvfs-gphoto2() {
@@ -101,12 +129,7 @@
pkgdesc+=" (gphoto2 backend; PTP camera, MTP media player)"
depends=("gvfs=$pkgver" libgphoto2)
- cd $pkgbase/daemon
- install -D .libs/gvfsd-gphoto2 "$pkgdir/usr/lib/gvfs/gvfsd-gphoto2"
- install -Dm644 gphoto2.mount "$pkgdir/usr/share/gvfs/mounts/gphoto2.mount"
-
- cd "$srcdir/$pkgbase/monitor/gphoto2"
- make DESTDIR="$pkgdir" install
+ mv "$srcdir/gphoto2" "$pkgdir/usr"
}
package_gvfs-mtp() {
@@ -113,12 +136,7 @@
pkgdesc+=" (MTP backend; Android, media player)"
depends=("gvfs=$pkgver" libmtp)
- cd $pkgbase/daemon
- install -D .libs/gvfsd-mtp "$pkgdir/usr/lib/gvfs/gvfsd-mtp"
- install -Dm644 mtp.mount "$pkgdir/usr/share/gvfs/mounts/mtp.mount"
-
- cd "$srcdir/$pkgbase/monitor/mtp"
- make DESTDIR="$pkgdir" install
+ mv "$srcdir/mtp" "$pkgdir/usr"
}
package_gvfs-goa() {
@@ -125,8 +143,7 @@
pkgdesc+=" (Gnome Online Accounts backend; cloud storage)"
depends=("gvfs=$pkgver" gnome-online-accounts)
- cd "$srcdir/$pkgbase/monitor/goa"
- make DESTDIR="$pkgdir" install
+ mv "$srcdir/goa" "$pkgdir/usr"
}
package_gvfs-nfs() {
@@ -134,9 +151,7 @@
depends=("gvfs=$pkgver" libnfs)
install=gvfs-nfs.install
- cd $pkgbase/daemon
- install -D .libs/gvfsd-nfs "$pkgdir/usr/lib/gvfs/gvfsd-nfs"
- install -Dm644 nfs.mount "$pkgdir/usr/share/gvfs/mounts/nfs.mount"
+ mv "$srcdir/nfs" "$pkgdir/usr"
}
package_gvfs-google() {
@@ -143,7 +158,5 @@
pkgdesc+=" (Google Drive backend)"
depends=("gvfs-goa=$pkgver" libgdata)
- cd $pkgbase/daemon
- install -D .libs/gvfsd-google "$pkgdir/usr/lib/gvfs/gvfsd-google"
- install -Dm644 google.mount "$pkgdir/usr/share/gvfs/mounts/google.mount"
+ mv "$srcdir/google" "$pkgdir/usr"
}
More information about the arch-commits
mailing list