[arch-commits] Commit in (4 files)

[Christian Rebischke]

    Date: Tuesday, March 13, 2018 @ 23:46:33
  Author: shibumi
Revision: 307500

pushed python-btchip back to community as dependency for electrum

Added:
  python-btchip/
  python-btchip/repos/
  python-btchip/trunk/
  python-btchip/trunk/PKGBUILD

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Added: python-btchip/trunk/PKGBUILD
===================================================================
--- python-btchip/trunk/PKGBUILD	                        (rev 0)
+++ python-btchip/trunk/PKGBUILD	2018-03-13 23:46:33 UTC (rev 307500)
@@ -0,0 +1,44 @@
+# $Id$
+# Maintainer: Christian Rebischke <chris.rebischke at archlinux.org>
+# Contributor: Timothy Redaelli <timothy.redaelli at gmail.com>
+# Contributor: Andy Weidenbaum <archbaum at gmail.com>
+
+pkgbase=python-btchip
+pkgname=(python-btchip python2-btchip)
+pkgver=0.1.26
+pkgrel=1
+pkgdesc="Python library to communicate with BTChip dongle"
+arch=('any')
+makedepends=(python-setuptools python2-setuptools)
+optdepends=('btchip-udev: access BTChip as non-root user')
+url="https://github.com/LedgerHQ/btchip-python"
+license=('Apache')
+source=($pkgname-$pkgver.tar.gz::https://github.com/LedgerHQ/btchip-python/archive/v$pkgver.tar.gz)
+sha256sums=('2afab0f326b96bd819e8bc9cb69edc7c55773741a50a5e5a36d224bcfd93a4a2')
+
+prepare() {
+  cp -r btchip-python-$pkgver btchip-python2-$pkgver
+}
+
+build() {
+  cd btchip-python-$pkgver
+  python setup.py build
+
+  cd ../btchip-python2-$pkgver
+  python2 setup.py build
+}
+
+package_python-btchip() {
+  depends=(python-hidapi)
+
+  cd btchip-python-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1
+}
+
+package_python2-btchip() {
+  depends=(python2-hidapi)
+
+  cd btchip-python2-$pkgver
+  python2 setup.py install --root="$pkgdir" --optimize=1
+}
+


Property changes on: python-btchip/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property