[arch-commits] Commit in lib32-libcurl-compat/repos (2 files)
Levente Polyak
anthraxx at archlinux.org
Wed Mar 14 16:59:54 UTC 2018
Date: Wednesday, March 14, 2018 @ 16:59:53
Author: anthraxx
Revision: 307783
archrelease: copy trunk to multilib-staging-x86_64
Added:
lib32-libcurl-compat/repos/multilib-staging-x86_64/
lib32-libcurl-compat/repos/multilib-staging-x86_64/PKGBUILD
(from rev 307782, lib32-libcurl-compat/trunk/PKGBUILD)
----------+
PKGBUILD | 58 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 58 insertions(+)
Copied: lib32-libcurl-compat/repos/multilib-staging-x86_64/PKGBUILD (from rev 307782, lib32-libcurl-compat/trunk/PKGBUILD)
===================================================================
--- multilib-staging-x86_64/PKGBUILD (rev 0)
+++ multilib-staging-x86_64/PKGBUILD 2018-03-14 16:59:53 UTC (rev 307783)
@@ -0,0 +1,58 @@
+# $Id$
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Piotr Balcerowski <piotr at balcerowski.org>
+
+pkgname=lib32-libcurl-compat
+pkgver=7.59.0
+pkgrel=1
+pkgdesc='An URL retrieval library (without versioned symbols)'
+arch=('x86_64')
+url='https://curl.haxx.se'
+license=('MIT')
+depends=('lib32-curl' 'lib32-glibc' 'lib32-krb5' 'lib32-libssh2' 'lib32-libpsl'
+ 'lib32-openssl' 'lib32-zlib' 'libcurl-compat')
+options=('strip')
+validpgpkeys=('27EDEAF22F3ABCEB50DB9A125CC908FDB71E12C2') # Daniel Stenberg
+source=("https://curl.haxx.se/download/curl-${pkgver}.tar.gz"{,.asc})
+sha512sums=('b61bced0ed8673a0358e0aaae545a7aba08eee460deee3140a45179a5846425066271566295d2cd0d8f05d84c1e3dc5e58d1f20863f7055f0f9853020cc7c76f'
+ 'SKIP')
+
+build() {
+ cd curl-${pkgver}
+
+ export CC='gcc -m32'
+ export PKG_CONFIG_PATH='/usr/lib32/pkgconfig'
+
+ ./configure \
+ --prefix='/usr' \
+ --libdir='/usr/lib32' \
+ --disable-ldap \
+ --disable-ldaps \
+ --disable-manual \
+ --disable-versioned-symbols \
+ --enable-ipv6 \
+ --enable-threaded-resolver \
+ --with-gssapi \
+ --with-random='/dev/urandom' \
+ --with-ca-bundle='/etc/ssl/certs/ca-certificates.crt'
+
+ sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+ make -C lib
+}
+
+package() {
+ cd curl-${pkgver}
+
+ make -C lib DESTDIR="${pkgdir}" install
+
+ mv "${pkgdir}"/usr/lib32/libcurl{,-compat}.so.4.5.0
+ rm "${pkgdir}"/usr/lib32/libcurl.{a,so}*
+ for version in 3 4.0.0 4.1.0 4.2.0 4.3.0 4.4.0; do
+ ln -s libcurl-compat.so.4.5.0 "${pkgdir}"/usr/lib32/libcurl.so.${version}
+ done
+
+ install -dm 755 "${pkgdir}"/usr/share/licenses
+ ln -s libcurl-compat "${pkgdir}"/usr/share/licenses/lib32-libcurl-compat
+}
+
+# vim: ts=2 sw=2 et:
More information about the arch-commits
mailing list