[arch-commits] Commit in lib32-curl/repos (2 files)

[Levente Polyak]

    Date: Wednesday, March 14, 2018 @ 17:20:40
  Author: anthraxx
Revision: 307789

archrelease: copy trunk to multilib-staging-x86_64

Added:
  lib32-curl/repos/multilib-staging-x86_64/
  lib32-curl/repos/multilib-staging-x86_64/PKGBUILD
    (from rev 307788, lib32-curl/trunk/PKGBUILD)

----------+
 PKGBUILD |   59 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)

Copied: lib32-curl/repos/multilib-staging-x86_64/PKGBUILD (from rev 307788, lib32-curl/trunk/PKGBUILD)
===================================================================
--- multilib-staging-x86_64/PKGBUILD	                        (rev 0)
+++ multilib-staging-x86_64/PKGBUILD	2018-03-14 17:20:40 UTC (rev 307789)
@@ -0,0 +1,59 @@
+# $Id$
+# Maintainer: Daniel Wallace <danielwallace at aur.archlinux.org>
+# Contributor: Dave Reisner <dreisner at archlinux.org>
+# Contributor: Angel Velasquez <angvp at archlinux.org>
+# Contributor: Eric Belanger <eric at archlinux.org>
+# Contributor: Lucien Immink <l.immink at student.fnt.hvu.nl>
+# Contributor: Daniel J Griffiths <ghost1227 at archlinux.us>
+
+pkgname=lib32-curl
+_pkgname=curl
+pkgver=7.59.0
+pkgrel=1
+pkgdesc="An URL retrieval utility and library (32-bit)"
+arch=('x86_64')
+url="https://curl.haxx.se"
+license=('MIT')
+depends=('lib32-libssh2' 'lib32-krb5' 'lib32-libpsl' 'lib32-zlib' "${_pkgname}")
+source=("https://curl.haxx.se/download/$_pkgname-$pkgver.tar.gz"{,.asc})
+sha512sums=('b61bced0ed8673a0358e0aaae545a7aba08eee460deee3140a45179a5846425066271566295d2cd0d8f05d84c1e3dc5e58d1f20863f7055f0f9853020cc7c76f'
+            'SKIP')
+validpgpkeys=('27EDEAF22F3ABCEB50DB9A125CC908FDB71E12C2'   # Daniel Stenberg
+              '914C533DF9B2ADA2204F586D78E11C6B279D5C91')  # Daniel Stenberg (old key)
+
+build() {
+  cd "$_pkgname-$pkgver"
+
+  export CC="gcc -m32"
+  export CXX="g++ -m32"
+  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
+
+  ./configure \
+      --prefix=/usr \
+      --mandir=/usr/share/man \
+      --disable-dependency-tracking \
+      --disable-ldap \
+      --disable-ldaps \
+      --enable-ipv6 \
+      --enable-manual \
+      --enable-versioned-symbols \
+      --enable-threaded-resolver \
+      --with-gssapi \
+      --with-random=/dev/urandom \
+      --with-ca-bundle=/etc/ssl/certs/ca-certificates.crt \
+      --libdir=/usr/lib32
+
+  make
+}
+
+package() {
+  cd "$_pkgname-$pkgver"
+
+  make DESTDIR="$pkgdir" install
+
+  rm -rf "${pkgdir}"/usr/{share,bin,include}
+
+  # license
+  install -d "$pkgdir/usr/share/licenses"
+  ln -s "$_pkgname" "$pkgdir/usr/share/licenses/$pkgname"
+}