[arch-commits] Commit in gtksourceview3/repos (2 files)

[Jan Steffens]

    Date: Wednesday, March 14, 2018 @ 18:07:55
  Author: heftig
Revision: 318984

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  gtksourceview3/repos/gnome-unstable-x86_64/
  gtksourceview3/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 318983, gtksourceview3/trunk/PKGBUILD)

----------+
 PKGBUILD |   40 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)

Copied: gtksourceview3/repos/gnome-unstable-x86_64/PKGBUILD (from rev 318983, gtksourceview3/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2018-03-14 18:07:55 UTC (rev 318984)
@@ -0,0 +1,40 @@
+# $Id$
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+
+pkgname=gtksourceview3
+pkgver=3.24.7
+pkgrel=1
+pkgdesc="A text widget adding syntax highlighting and more to GNOME"
+url="https://wiki.gnome.org/Projects/GtkSourceView"
+arch=(x86_64)
+license=(GPL)
+depends=(gtk3 libxml2)
+makedepends=(intltool gobject-introspection glade vala gtk-doc autoconf-archive git)
+_commit=7bce982b9925fbeafeac73ae8ca48bf70c95a1e7  # tags/3.24.7^0
+source=("git+https://git.gnome.org/browse/gtksourceview#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd gtksourceview
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd gtksourceview
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd gtksourceview
+  ./configure --prefix=/usr --sysconfdir=/etc \
+      --localstatedir=/var --disable-static \
+      --enable-glade-catalog --enable-gtk-doc --disable-Werror
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+package() {
+  cd gtksourceview
+  make DESTDIR="$pkgdir" install
+}