[arch-commits] Commit in gnome-calendar/repos (3 files)
Jan Steffens
heftig at archlinux.org
Wed Mar 14 20:42:07 UTC 2018
Date: Wednesday, March 14, 2018 @ 20:42:06
Author: heftig
Revision: 319123
archrelease: copy trunk to gnome-unstable-x86_64
Added:
gnome-calendar/repos/gnome-unstable-x86_64/
gnome-calendar/repos/gnome-unstable-x86_64/PKGBUILD
(from rev 319122, gnome-calendar/trunk/PKGBUILD)
gnome-calendar/repos/gnome-unstable-x86_64/null-icaltime.diff
(from rev 319122, gnome-calendar/trunk/null-icaltime.diff)
--------------------+
PKGBUILD | 44 ++++++++++++++++++++++++++++++++++++++++++++
null-icaltime.diff | 14 ++++++++++++++
2 files changed, 58 insertions(+)
Copied: gnome-calendar/repos/gnome-unstable-x86_64/PKGBUILD (from rev 319122, gnome-calendar/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD 2018-03-14 20:42:06 UTC (rev 319123)
@@ -0,0 +1,44 @@
+# $Id$
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+
+pkgname=gnome-calendar
+pkgver=3.28.0.1+2+geb41e059
+pkgrel=1
+pkgdesc="Simple and beautiful calendar application designed to perfectly fit the GNOME desktop"
+url="https://wiki.gnome.org/Apps/Calendar"
+arch=(x86_64)
+license=(GPL)
+depends=(evolution-data-server gsettings-desktop-schemas evolution gnome-control-center libdazzle)
+makedepends=(python appstream-glib git meson gtk-doc)
+groups=(gnome)
+_commit=eb41e059777f903422c73f5afd822782e178c0ef # gnome-3-28
+source=("git+https://gitlab.gnome.org/GNOME/gnome-calendar.git#commit=$_commit"
+ null-icaltime.diff)
+sha256sums=('SKIP'
+ 'c1aa738a4ff275f725d0aa5406312600503b2b59270448a9e6b30b82a924dc27')
+
+pkgver() {
+ cd $pkgname
+ git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+ cd $pkgname
+ patch -Np1 -i ../null-icaltime.diff
+}
+
+build() {
+ arch-meson $pkgname build -D gtk_doc=true
+ ninja -C build
+}
+
+check() {
+ cd build
+ meson test
+}
+
+package() {
+ DESTDIR="$pkgdir" ninja -C build install
+}
+
+# vim:set ts=2 sw=2 et:
Copied: gnome-calendar/repos/gnome-unstable-x86_64/null-icaltime.diff (from rev 319122, gnome-calendar/trunk/null-icaltime.diff)
===================================================================
--- gnome-unstable-x86_64/null-icaltime.diff (rev 0)
+++ gnome-unstable-x86_64/null-icaltime.diff 2018-03-14 20:42:06 UTC (rev 319123)
@@ -0,0 +1,14 @@
+diff --git i/src/gcal-utils.c w/src/gcal-utils.c
+index c7646565..8070034c 100644
+--- i/src/gcal-utils.c
++++ w/src/gcal-utils.c
+@@ -181,6 +181,9 @@ icaltime_to_datetime (const icaltimetype *date)
+ GDateTime *dt;
+ GTimeZone *tz;
+
++ if (!date)
++ return NULL;
++
+ tz = date->zone ? g_time_zone_new (icaltime_get_tzid (*date)) : g_time_zone_new_utc ();
+ dt = g_date_time_new (tz,
+ date->year,
More information about the arch-commits
mailing list