[arch-commits] Commit in gnome-software/repos (2 files)

[Bartłomiej Piotrowski]

    Date: Thursday, March 15, 2018 @ 07:56:10
  Author: bpiotrowski
Revision: 308391

archrelease: copy trunk to community-staging-x86_64

Added:
  gnome-software/repos/community-staging-x86_64/
  gnome-software/repos/community-staging-x86_64/PKGBUILD
    (from rev 308389, gnome-software/trunk/PKGBUILD)

----------+
 PKGBUILD |   57 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)

Copied: gnome-software/repos/community-staging-x86_64/PKGBUILD (from rev 308389, gnome-software/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-03-15 07:56:10 UTC (rev 308391)
@@ -0,0 +1,57 @@
+# $Id$
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+# Contributor: Yosef Or Boczko <yoseforb at gnome.org>
+
+pkgbase=gnome-software
+pkgname=(gnome-software gnome-software-packagekit-plugin)
+pkgver=3.28.0
+pkgrel=1
+pkgdesc="GNOME Software Tools"
+url="https://wiki.gnome.org/Apps/Software/"
+arch=(x86_64)
+license=(GPL2)
+makedepends=(appstream-glib gnome-desktop gtkspell3 libpackagekit-glib flatpak fwupd ostree
+             docbook-xsl git gobject-introspection gtk-doc meson valgrind gspell)
+_commit=299554f4a23e39f5d0b0e4d8f59a4beb2954ffa0  # tags/3.28.0^0
+source=("git+https://gitlab.gnome.org/GNOME/gnome-software.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgbase
+  git describe --tags | sed 's/^GNOME_SOFTWARE_//;s/_/./g;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgbase
+}
+
+build() {
+  arch-meson $pkgbase build \
+    -D enable-rpm=false \
+    -D enable-ubuntuone=false \
+    -D enable-ubuntu-reviews=false
+  ninja -C build
+}
+
+package_gnome-software() {
+  groups=('gnome')
+  depends=(appstream-glib gnome-desktop gsettings-desktop-schemas gtkspell3 libpackagekit-glib gspell)
+  optdepends=('flatpak: Flatpak support plugin'
+              'fwupd: fwupd support plugin'
+              'ostree: OSTree support plugin')
+
+  DESTDIR="$pkgdir" ninja -C build install
+
+  # Split out packagekit plugin
+  mkdir "$srcdir"/packagekit-plugin
+  mv "$pkgdir"/usr/lib/gs-plugins-11/libgs_plugin_{packagekit*,systemd-updates}.so "$srcdir"/packagekit-plugin
+}
+
+package_gnome-software-packagekit-plugin() {
+  pkgdesc="PackageKit support plugin for GNOME Software"
+  depends=(archlinux-appstream-data gnome-software packagekit)
+
+  mkdir -p "$pkgdir"/usr/lib/gs-plugins-11
+  mv "$srcdir"/packagekit-plugin/* "$pkgdir"/usr/lib/gs-plugins-11/
+}