[arch-commits] Commit in kdevelop/repos (staging-x86_64 staging-x86_64/PKGBUILD)
Antonio Rojas
arojas at archlinux.org
Fri Mar 16 14:25:45 UTC 2018
Date: Friday, March 16, 2018 @ 14:25:45
Author: arojas
Revision: 319525
archrelease: copy trunk to staging-x86_64
Added:
kdevelop/repos/staging-x86_64/
kdevelop/repos/staging-x86_64/PKGBUILD
(from rev 319524, kdevelop/trunk/PKGBUILD)
----------+
PKGBUILD | 55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 55 insertions(+)
Copied: kdevelop/repos/staging-x86_64/PKGBUILD (from rev 319524, kdevelop/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD (rev 0)
+++ staging-x86_64/PKGBUILD 2018-03-16 14:25:45 UTC (rev 319525)
@@ -0,0 +1,55 @@
+# $Id$
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+# Contributor: Giovanni Scafora <giovanni at archlinux.org>
+
+pkgname=kdevelop
+pkgver=5.2.1
+pkgrel=3
+pkgdesc='C++ IDE using KDE technologies'
+arch=(x86_64)
+url='http://www.kdevelop.org/'
+license=(GPL)
+depends=(clang libksysguard kitemmodels knotifyconfig ktexteditor grantlee libkomparediff2 qt5-webengine
+ kcmutils threadweaver knewstuff)
+makedepends=(extra-cmake-modules kdoctools kdevelop-pg-qt llvm qt5-tools plasma-framework krunner okteta python mesa
+ boost purpose subversion)
+optdepends=('konsole: embedded terminal'
+ 'git: Git support' 'subversion: SVN support' 'cvs: CVS support'
+ 'gdb: GNU debugger support' 'lldb: LLDB debugger support'
+ 'qt5-doc: Qt documentation integration'
+ 'cmake: cmake integration'
+ 'qt5-tools: qthelp plugin'
+ 'okteta: GNU debugger support'
+ 'plasma-framework: for the plasma addons'
+ 'purpose: patch review plugin'
+ 'cppcheck: code analyzer' 'heaptrack: memory profiler')
+conflicts=(kdevelop-qmljs kdevplatform)
+replaces=(kdevelop-qmljs kdevplatform)
+source=("https://download.kde.org/stable/$pkgname/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.asc}
+ kdebug-386720.patch::"https://cgit.kde.org/kdevelop.git/patch/?id=f2a6941e")
+sha256sums=('d1c39c563e4fada89eb9f30bd43c6c4beed0fec7ca7d124af587193cfe020650'
+ 'SKIP'
+ '9e52906314f25f036e3c7a9c8d825dd6b196fed70437c6d09ce155ccaaab7591')
+validpgpkeys=('329FD02C5AA48FCC77A4BBF0AC44AC6DB29779E6') # Sven Brauch <mail at svenbrauch.de>
+
+prepare() {
+ mkdir -p build
+
+ cd $pkgname-$pkgver
+ patch -p1 -i ../kdebug-386720.patch # Fix performance issue
+}
+
+build() {
+ cd build
+ cmake ../$pkgname-$pkgver \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DCMAKE_INSTALL_LIBDIR=lib \
+ -DBUILD_TESTING=OFF
+ make
+}
+
+package() {
+ cd build
+ make DESTDIR="$pkgdir" install
+}
More information about the arch-commits
mailing list