[arch-commits] Commit in gnote/repos (testing-x86_64 testing-x86_64/PKGBUILD)

[Jan de Groot]

    Date: Sunday, March 18, 2018 @ 22:43:27
  Author: jgc
Revision: 319613

archrelease: copy trunk to testing-x86_64

Added:
  gnote/repos/testing-x86_64/
  gnote/repos/testing-x86_64/PKGBUILD
    (from rev 319612, gnote/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: gnote/repos/testing-x86_64/PKGBUILD (from rev 319612, gnote/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2018-03-18 22:43:27 UTC (rev 319613)
@@ -0,0 +1,52 @@
+# $Id$
+# Maintainer:  Ionut Biru <ibiru at archlinux.org>
+# Contributor: uastasi <uastasi at archlinux.us>
+
+pkgname=gnote
+pkgver=3.28.0
+pkgrel=1
+pkgdesc="A note taking application"
+url="https://wiki.gnome.org/Apps/Gnote"
+arch=(x86_64)
+license=(GPL3)
+depends=(gtkmm3 gtkspell3 libxslt dconf libsecret)
+makedepends=(intltool itstool boost yelp-tools autoconf-archive git)
+_commit=49dc02ae9c052367b560db6794d604c08efdd605  # tags/3.28.0^0
+source=("git+https://git.gnome.org/browse/gnote#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+
+  # Work around aclocal exiting with "too many loops"
+  cp /usr/share/aclocal/ax_require_defined.m4 m4
+
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr \
+    --sysconfdir=/etc \
+    --localstatedir=/var \
+    --libexecdir=/usr/lib/$pkgname \
+    --disable-schemas-compile \
+    --disable-static
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+check() {
+  cd $pkgname
+  make check
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+}