[arch-commits] Commit in libnice/repos (testing-x86_64 testing-x86_64/PKGBUILD)

[Jan Steffens]

    Date: Thursday, March 22, 2018 @ 09:07:47
  Author: heftig
Revision: 319808

archrelease: copy trunk to testing-x86_64

Added:
  libnice/repos/testing-x86_64/
  libnice/repos/testing-x86_64/PKGBUILD
    (from rev 319807, libnice/trunk/PKGBUILD)

----------+
 PKGBUILD |   39 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)

Copied: libnice/repos/testing-x86_64/PKGBUILD (from rev 319807, libnice/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2018-03-22 09:07:47 UTC (rev 319808)
@@ -0,0 +1,39 @@
+# $Id$
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+# Contributor: William Díaz <wdiaz at archlinux.us>
+
+pkgname=libnice
+pkgver=0.1.14+70+gfb2f1f7
+pkgrel=1
+pkgdesc="An implementation of the IETF's draft ICE (for p2p UDP data streams)"
+url="https://nice.freedesktop.org"
+arch=(x86_64)
+license=(LGPL)
+depends=(glib2 gnutls)
+makedepends=(gstreamer gtk-doc git)
+optdepends=(gstreamer)
+_commit=fb2f1f77a31baa91968fc81c205f980b6913f403  # master
+source=("git+https://anongit.freedesktop.org/git/libnice/libnice#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr --disable-static --with-gstreamer-0.10=no --enable-gtk-doc
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+}