[arch-commits] Commit in haskell-xml-conduit/repos (2 files)

[Felix Yan]

    Date: Thursday, March 22, 2018 @ 19:26:29
  Author: felixonmars
Revision: 310742

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-xml-conduit/repos/community-staging-x86_64/
  haskell-xml-conduit/repos/community-staging-x86_64/PKGBUILD
    (from rev 310741, haskell-xml-conduit/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: haskell-xml-conduit/repos/community-staging-x86_64/PKGBUILD (from rev 310741, haskell-xml-conduit/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-03-22 19:26:29 UTC (rev 310742)
@@ -0,0 +1,47 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=xml-conduit
+pkgname=haskell-xml-conduit
+pkgver=1.7.1.2
+pkgrel=23
+pkgdesc="Pure-Haskell utilities for dealing with XML with the conduit package."
+url="https://github.com/snoyberg/xml"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-attoparsec' 'haskell-blaze-builder' 'haskell-text'
+         'haskell-blaze-markup' 'haskell-conduit' 'haskell-conduit-extra'
+         'haskell-data-default-class' 'haskell-monad-control' 'haskell-resourcet'
+         'haskell-blaze-html' 'haskell-xml-types')
+makedepends=('ghc' 'haskell-hspec' 'haskell-hunit')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('da9d8af3f3f8cc0a88557d42edce1aa5cf965d3a87a1dcf8db3fc2dd8bee8ccdf574f9a7b091b94f6831f824b56e2598c5a0ba94d0d16edff47f2d7e9217448c')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}