[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Friday, March 23, 2018 @ 07:13:13
  Author: felixonmars
Revision: 311190

addpkg: python-kiwisolver 1.0.1-1

Added:
  python-kiwisolver/
  python-kiwisolver/repos/
  python-kiwisolver/trunk/
  python-kiwisolver/trunk/PKGBUILD

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Added: python-kiwisolver/trunk/PKGBUILD
===================================================================
--- python-kiwisolver/trunk/PKGBUILD	                        (rev 0)
+++ python-kiwisolver/trunk/PKGBUILD	2018-03-23 07:13:13 UTC (rev 311190)
@@ -0,0 +1,49 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-kiwisolver
+pkgname=(python-kiwisolver python2-kiwisolver)
+pkgver=1.0.1
+pkgrel=1
+pkgdesc="A fast implementation of the Cassowary constraint solver"
+url="https://github.com/nucleic/kiwi"
+license=('PerlArtistic')
+arch=('x86_64')
+makedepends=('python-setuptools' 'python2-setuptools')
+checkdepends=('python-pytest-runner' 'python2-pytest-runner')
+source=("$pkgbase-$pkgver.tar.gz::https://github.com/nucleic/kiwi/archive/$pkgver.tar.gz")
+sha512sums=('01002ae1dbf6482ed68c49ad3da80b772db84ec221c4b111c42f1b493f19299e0ddb187e43e64b380eb2ddc292d5848d6e09a5a1dbfaf68950a65423a913ec18')
+
+prepare() {
+  cp -a kiwi-$pkgver{,-py2}
+}
+
+build() {
+  cd "$srcdir"/kiwi-$pkgver/
+  python setup.py build
+
+  cd "$srcdir"/kiwi-$pkgver-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/kiwi-$pkgver/
+  python setup.py pytest
+
+  cd "$srcdir"/kiwi-$pkgver-py2
+  python2 setup.py pytest
+}
+
+package_python-kiwisolver() {
+  depends=('python-setuptools')
+
+  cd kiwi-$pkgver/
+  python3 setup.py install --root="$pkgdir" --optimize=1
+}
+
+package_python2-kiwisolver() {
+  depends=('python2-setuptools')
+
+  cd kiwi-$pkgver-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+}


Property changes on: python-kiwisolver/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property