[arch-commits] Commit in gtk-doc/repos (testing-any testing-any/PKGBUILD)

[Jan Steffens]

    Date: Saturday, March 24, 2018 @ 15:37:14
  Author: heftig
Revision: 320140

archrelease: copy trunk to testing-any

Added:
  gtk-doc/repos/testing-any/
  gtk-doc/repos/testing-any/PKGBUILD
    (from rev 320139, gtk-doc/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: gtk-doc/repos/testing-any/PKGBUILD (from rev 320139, gtk-doc/trunk/PKGBUILD)
===================================================================
--- testing-any/PKGBUILD	                        (rev 0)
+++ testing-any/PKGBUILD	2018-03-24 15:37:14 UTC (rev 320140)
@@ -0,0 +1,44 @@
+# $Id$
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+
+pkgname=gtk-doc
+pkgver=1.28
+pkgrel=1
+pkgdesc="Documentation tool for public library API"
+url="https://www.gtk.org/gtk-doc/"
+arch=(any)
+license=(GPL FDL)
+depends=(docbook-xsl docbook-xml source-highlight glib2-docs python-six python-lxml
+         python-pygments python-anytree)
+makedepends=(dblatex git yelp-tools)
+checkdepends=(bc gtk3)
+optdepends=('dblatex: PDF support')
+_commit=695816a36b492140529ed84c59ee246be2b952b7  # tags/GTK_DOC_1_28^0
+source=("git+https://git.gnome.org/browse/gtk-doc#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed -e 's/GTK_DOC_//' -e 's/_/\./g' -e 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr --disable-static
+  make
+}
+
+check() {
+  cd $pkgname
+  make check
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+}