[arch-commits] Commit in lsof/repos (3 files)

[Anatol Pomozov]

    Date: Sunday, March 25, 2018 @ 20:57:27
  Author: anatolik
Revision: 320321

archrelease: copy trunk to testing-x86_64

Added:
  lsof/repos/testing-x86_64/
  lsof/repos/testing-x86_64/PKGBUILD
    (from rev 320320, lsof/trunk/PKGBUILD)
  lsof/repos/testing-x86_64/license.txt
    (from rev 320320, lsof/trunk/license.txt)

-------------+
 PKGBUILD    |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 license.txt |   27 +++++++++++++++++++++++++++
 2 files changed, 80 insertions(+)

Copied: lsof/repos/testing-x86_64/PKGBUILD (from rev 320320, lsof/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2018-03-25 20:57:27 UTC (rev 320321)
@@ -0,0 +1,53 @@
+# $Id$
+# Maintainer: Tom Gundersen <teg at jklm.no>
+# Contributor: Angel Velasquez <angvp at archlinux.org> 
+# Contributor: Daniel J Griffiths <ghost1227 at archlinux.us>
+# Contributor: Aaron Griffin <aaron at archlinux.org>
+# Contributor: Jochem Kossen <j.kossen at home.nl>
+
+pkgname=lsof
+pkgver=4.90
+pkgrel=2
+pkgdesc="Lists open files for running Unix processes"
+arch=('x86_64')
+url="http://people.freebsd.org/~abe/"
+license=('custom')
+depends=('glibc')
+source=(ftp://ftp.fu-berlin.de/pub/unix/tools/lsof/lsof_$pkgver.tar.bz2
+        fix_excessive_reporting.patch::https://github.com/masatake/lsof-linux/commit/f5d024877006deb5d0a500235068f8c4f928939e.patch
+        license.txt)
+sha1sums=('9980f2ed68242c292f7aeb077d450c1e911ded88'
+          '6d5b5ab446e85253af287d1adbb9feec95fbcde5'
+          'db6b6d90ce895e4053f91ad25c7761fbf9a37dd6')
+#validpgpkeys=(9AFD62A840BD3D55) It is PGP-2 key
+
+prepare() {
+	cd lsof_$pkgver
+	tar xf lsof_${pkgver}_src.tar
+	cd lsof_${pkgver}_src
+	sed -i 's|/\* #define\tHASSECURITY\t1 \*/|#define\tHASSECURITY\t1|' dialects/linux/machine.h
+
+	patch -p1 < $srcdir/fix_excessive_reporting.patch
+}
+
+build() {
+	cd lsof_$pkgver/lsof_${pkgver}_src
+	./Configure -n linux
+	make 
+}
+
+check() {
+	cd lsof_$pkgver/lsof_${pkgver}_src/tests
+	sed 's/END=0/exit 0/' -i CkTestDB
+	make all
+}
+
+package() {
+	cd lsof_$pkgver/lsof_${pkgver}_src
+
+	install -Dm0755 lsof "$pkgdir"/usr/bin/lsof 
+	install -Dm0644 lsof.8 "$pkgdir"/usr/share/man/man8/lsof.8 
+   
+	install -D -m0644 "$srcdir"/license.txt \
+	     "$pkgdir"/usr/share/licenses/lsof/LICENSE 
+}

Copied: lsof/repos/testing-x86_64/license.txt (from rev 320320, lsof/trunk/license.txt)
===================================================================
--- testing-x86_64/license.txt	                        (rev 0)
+++ testing-x86_64/license.txt	2018-03-25 20:57:27 UTC (rev 320321)
@@ -0,0 +1,27 @@
+Copyright 2002 Purdue Research Foundation, West Lafayette,
+Indiana 47907.  All rights reserved.
+
+Written by Victor A. Abell
+
+This software is not subject to any license of the American
+Telephone and Telegraph Company or the Regents of the
+University of California.
+
+Permission is granted to anyone to use this software for
+any purpose on any computer system, and to alter it and
+redistribute it freely, subject to the following
+restrictions:
+
+1. Neither the authors nor Purdue University are responsible
+   for any consequences of the use of this software.
+
+2. The origin of this software must not be misrepresented,
+   either by explicit claim or by omission.  Credit to the
+   authors and Purdue University must appear in documentation
+   and sources.
+
+3. Altered versions must be plainly marked as such, and must
+   not be misrepresented as being the original software.
+
+4. This notice may not be removed or altered.
+