[arch-commits] Commit in libsecret/repos (testing-x86_64 testing-x86_64/PKGBUILD)

[Jan Steffens]

    Date: Thursday, March 29, 2018 @ 17:04:14
  Author: heftig
Revision: 320622

archrelease: copy trunk to testing-x86_64

Added:
  libsecret/repos/testing-x86_64/
  libsecret/repos/testing-x86_64/PKGBUILD
    (from rev 320621, libsecret/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: libsecret/repos/testing-x86_64/PKGBUILD (from rev 320621, libsecret/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2018-03-29 17:04:14 UTC (rev 320622)
@@ -0,0 +1,45 @@
+# $Id$
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+
+pkgname=libsecret
+pkgver=0.18.6
+pkgrel=1
+pkgdesc="Library for storing and retrieving passwords and other secrets"
+arch=(x86_64)
+license=(LGPL)
+url="https://wiki.gnome.org/Projects/Libsecret"
+depends=(glib2 libgcrypt)
+checkdepends=(python-dbus dbus-glib python-gobject gjs)
+makedepends=(intltool docbook-xsl gobject-introspection vala git gtk-doc)
+optdepends=('gnome-keyring: key storage service (or use any other service implementing org.freedesktop.secrets)')
+_commit=b01e54991a7f067e24a4f309690ea2c9233d1a35  # tags/0.18.6^0
+source=("git+https://git.gnome.org/browse/libsecret#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
+    --disable-static --enable-gtk-doc
+  make
+}
+
+check() {
+  cd $pkgname
+  # Our containers have no secmem
+  dbus-run-session make -k check || :
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+}