[arch-commits] Commit in (4 files)
David Runge
dvzrv at archlinux.org
Sat Mar 31 21:51:17 UTC 2018
Date: Saturday, March 31, 2018 @ 21:51:17
Author: dvzrv
Revision: 313652
Adding zam-plugins 3.10.
Added:
zam-plugins/
zam-plugins/repos/
zam-plugins/trunk/
zam-plugins/trunk/PKGBUILD
----------+
PKGBUILD | 38 ++++++++++++++++++++++++++++++++++++++
1 file changed, 38 insertions(+)
Added: zam-plugins/trunk/PKGBUILD
===================================================================
--- zam-plugins/trunk/PKGBUILD (rev 0)
+++ zam-plugins/trunk/PKGBUILD 2018-03-31 21:51:17 UTC (rev 313652)
@@ -0,0 +1,38 @@
+# Maintainer: David Runge <dave at sleepmap.de>
+pkgname=zam-plugins
+pkgver=3.10
+pkgrel=3
+pkgdesc="Collection of LADSPA/LV2/VST/JACK audio plugins for high-quality processing"
+arch=('x86_64')
+url="https://github.com/zamaudio/zam-plugins"
+license=('GPL2')
+groups=('ladspa-plugins' 'lv2-plugins' 'pro-audio' 'vst-plugins')
+depends=('fftw' 'libglvnd' 'jack' 'liblo' 'zita-convolver')
+makedepends=('git' 'ladspa' 'libx11' 'libgl' 'liblo' 'lv2')
+source=("$pkgname-$pkgver::git+https://github.com/zamaudio/${pkgname}.git#tag=${pkgver}"
+ "git+https://github.com/distrho/dpf.git")
+md5sums=('SKIP'
+ 'SKIP')
+
+prepare() {
+ cd "$pkgname-$pkgver"
+ git submodule init
+ git config submodule.dpf.url "${srcdir}/dpf"
+ git submodule update
+ # use system zita-convolver
+ sed -e 's|\"../../lib/zita-convolver-3.1.0/zita-convolver.h\"|<zita-convolver.h>|' \
+ -i plugins/Zam{Verb,HeadX2}/convolution.{cpp,hpp}
+}
+
+build() {
+ cd "$pkgname-$pkgver"
+ make
+}
+
+package() {
+ cd "$pkgname-$pkgver"
+ make DESTDIR="$pkgdir/" PREFIX='/usr' install
+ # docs
+ install -t "${pkgdir}/usr/share/doc/${pkgname}/" \
+ -vDm 644 {README.md,changelog}
+}
Property changes on: zam-plugins/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
More information about the arch-commits
mailing list